2 Metode Batch Hapus Semua Kontak tanpa Alamat Email di Outlook Anda

Jika Anda menemukan beberapa kontak tidak memiliki alamat email di Outlook Anda, Anda mungkin ingin memproses setiap folder Kontak untuk menghapus semua kontak tersebut. Artikel ini akan membagikan 2 cara kepada Anda.

Mungkin Anda memiliki banyak kontak di Outlook Anda dan beberapa di antaranya tidak memiliki alamat email. Jika menurut Anda mereka tidak lagi berguna, Anda harus berharap untuk menghapus semua kontak tanpa alamat email. Dengan cara standar, Anda dapat menggunakan "Pencarian Instan" untuk menemukannya dan kemudian menghapusnya secara manual, seperti Metode 1. Namun, ini agak membosankan. Oleh karena itu, dalam Metode 2, kami akan mengajari Anda cara lain yang lebih efisien.

Metode 1: Hapus Secara Manual setelah Menemukan Kontak tanpa Alamat Email

1. Sebagai langkah awal, tekan tombol “Ctrl + 3” untuk mengakses panel “Kontak”.
2. Kemudian, klik di kotak pencarian.
3. Selanjutnya, di pita "Pencarian" yang muncul, klik "Semua Item Kontak".
4. Selanjutnya, klik "Memiliki Alamat"> "Memiliki Alamat Email".
5. Setelah itu, kriteria “NOT emailaddresses: = []” akan ditambahkan ke kotak pencarian. Anda perlu menghapus "TIDAK".
6. Selanjutnya, semua kontak tanpa alamat email akan dicantumkan.
7. Sekarang, Anda harus memilih kontak di hasil pencarian secara manual karena grup kontak Anda juga harus ada dalam daftar.
8. Terakhir, tekan tombol "Del" untuk menghapus semua kontak yang dipilih.

Metode 2: Hapus Batch Semua Kontak tanpa Alamat Email dengan VBA

1. Pertama-tama, ketuk "Alt + F11" untuk meluncurkan editor VBA di Outlook.
2. Di layar baru, salin kode VBA berikut ke dalam modul.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Kemudian, klik subrutin “BatchDeleteAllContactsWithoutEmailAddress”.
4. Akhirnya, tekan "F5" untuk memicu makro ini.
5. Setelah selesai, Anda akan mendapatkan pesan tentang hasilnya, seperti gambar di bawah ini.
6. Semua kontak tanpa alamat email telah dipindahkan ke folder "Item yang Dihapus".

Jauhkan Jauh dari Semua Potensi Risiko

Outlook dapat rusak karena berbagai faktor, seperti virus, kesalahan pengguna, kegagalan perangkat lunak, serta kesalahan perangkat keras. Anda harus enggan mengalami kerusakan Outlook, jadi Anda harus menjauhkan semua potensi risiko ini. Misalnya, Anda perlu memasang perangkat lunak antivirus yang kuat di PC Anda. Plus, Anda harus mencadangkan data Outlook Anda secara teratur. Last but not least, Anda sebaiknya menyiapkan alat perbaikan yang kuat dan andal, seperti DataNumen Outlook Repair. Ini dapat memperbaiki file PST korup mengajukan dengan mudah.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server korupsi dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com