2 Metode Cepat untuk Menambah Tanda Kurung Persegi untuk Mencatat Angka dalam Dokumen Word Anda

Dalam hal hari iniost, kami dengan senang hati menunjukkan kepada Anda 2 metode cepat untuk menambahkan tanda kurung siku untuk mencatat angka di dokumen Word Anda.

Setiap kali menyusun dokumen panjang, kami cenderung memasukkan catatan kaki dan catatan akhir. Kami tahu ada opsi untuk format angka lebih banyak. Namun, tidak ada gaya angka bawaan dengan tanda kurung siku. Apa yang akan kita bahas dalam teks-teks mendatang adalah 2 solusi untuk mengatasi masalah seperti itu.

Metode 1: Gunakan Fungsi "Temukan dan Ganti"

1. Untuk memulai, klik tab "Beranda" di in tardapatkan dokumen.
2. Kemudian klik perintah "Ganti" di grup "Pengeditan" untuk membuka kotak dialog "Temukan dan Ganti".
3. Sekarang jika Anda bekerja dengan catatan kaki, masukkan "^f" di kotak teks "Temukan apa".
4. Masukkan “[^&]” di kotak teks “Ganti dengan”.
5. Selanjutnya klik "Ganti Semua".
6. Hal berikutnya yang Anda lihat adalah semua nomor catatan kaki berada dalam tanda kurung siku. Klik "OK" untuk menutup kotak pesan.

Selain itu, untuk menambahkan tanda kurung siku ke catatan akhir, cukup ganti “^f” dengan “^e” di kotak teks “Temukan apa”.

Metode 2: Jalankan Makro Kata

1. Pertama dan depanost, tekan “Alt+ F11” di Word untuk memicu editor VBA.
2. Selanjutnya klik "Normal" dan kemudian tab "Sisipkan".
3. Pada menu drop-down, pilih "Module".
4. Kemudian klik dua kali pada modul yang baru dimasukkan untuk membuka area pengeditan di sisi kanan.
5. Dan rekatkan makro di bawah ini di sana:

Sub AddBracketForFootnoteAndEndnote()
  Application.ScreenUpdating = False
 
  Dim objRange As Range
 
  With ActiveDocument

    '  add bracket for footnotes. 
    If ActiveDocument.Footnotes.Count > 0 Then
      Call UpdateFootnoteRange(.Range)
      For Each objRange In .StoryRanges
        If objRange.StoryType = wdFootnotesStory Then
          Call UpdateFootnoteRange(objRange): Exit For
        End If
      Next
      MsgBox ("All footnotes have been added brackets.")
    Else
      MsgBox ("There is no footnote in this document")
    End If

    '  add bracket for footnotes. 
    If ActiveDocument.Endnotes.Count > 0 Then
      Call UpdateEndnoteRange(.Range)
      For Each objRange In .StoryRanges
        If objRange.StoryType = wdEndnotesStory Then
          Call UpdateEndnoteRange(objRange): Exit For
        End If
      Next
      MsgBox ("All endnotes have been added brackets.")
    Else
      MsgBox ("There is no endnote in this document")
    End If
  End With
 
  Application.ScreenUpdating = True
End Sub

Sub UpdateFootnoteRange(objRange As Range)
  With objRange.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^f"
    .Replacement.Text = "[^&]"
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchByte = True
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute Replace:=wdReplaceAll
  End With
End Sub

Sub UpdateEndnoteRange(objRange As Range)
  With objRange.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^e"
    .Replacement.Text = "[^&]"
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchByte = True
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute Replace:=wdReplaceAll
  End With
End Sub

6. Sekarang tempatkan pointer penyisipan di dalam makro pertama dan klik "Jalankan".
7. Kemudian pertama ada kotak pesan yang mengatakan tanda kurung siku telah ditambahkan ke semua nomor catatan kaki.
8. Selanjutnya ada yang kedua mengatakan konversi selesai di semua nomor catatan akhir.

Berikut adalah hasil yang kami dapatkan:

Mencegah Kehilangan Dokumen

Dengan data yang sama berharganya dengan apa yang kami simpan, kami tidak dapat mengambil risiko apa pun. Oleh karena itu, akan lebih bijaksana untuk mencadangkan file penting sebelum mengambil langkah apa pun dengan potensi risiko merusaknya, kecuali jika Anda ingin mendapatkan doc rusak.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk xls korupsi ke pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com