Ինչպե՞ս արագ գտնել մեկ նախադասության պարբերություններ ձեր Word փաստաթղթում

Այս գրառման մեջ մենք ցանկանում ենք ձեզ ցույց տալ, թե ինչպես արագ գտնել ձեր Word փաստաթղթի բոլոր մեկ նախադասությունից բաղկացած պարբերությունները VBA-ի միջոցով։

Երբեմն, որոշ փաստաթղթեր կարող են ունենալ շատ առանձնահատուկ պահանջներ դրանց ձևավորման և կառուցվածքների վերաբերյալ: Օրինակ ՝ հնարավոր է, որ ձեզ թույլ չտա ունենալ միայն մեկ նախադասությամբ պարբերություններ: Այս պարբերությունները դժվար է ճանաչել, բայց դա ժամանակ է պահանջում, հատկապես երկար փաստաթուղթ է:

Այսօր մենք ձեզ կառաջարկենք ձեր փաստաթղթում բոլոր մեկ նախադասությամբ պարբերությունները ճշգրտելու արագ միջոց:

Գտեք մեկ նախադասության բոլոր պարբերությունները մեկ փաստաթղթում

1. Նախ, Word- ը ժամանակահատվածը համարում է նախադասություն: Այսպիսով, եթե կան այնպիսի բառեր, ինչպիսիք են «պարոն» կամ «տիկին», Word- ը դա համարում է նախադասություն: Նման շեղումը բացառելու համար հարկավոր է փոխարինել «պարոնին» «պարոն» -ի հետ: Եվ ավարտելուց հետո գտեք մեկ նախադասության պարբերությունը, կարող եք դրանք հետ փոխել: Բառերը փոխարինելու համար կարող եք հղվել այս հղումով ՝ Ինչպես գտնել և փոխարինել ձեր Word փաստաթղթում առկա բազմաթիվ իրեր
2. Երկրորդ, սեղմեք «Alt + F11» ՝ VBA խմբագիր գործարկելու համար:
3. Դրանից հետո կտտացրեք «Նորմալ» նախագիծը:
4. Clickանկի տողի վրա կտտացրեք «sertետեղել» ներդիրին և դրա ընտրացանկում ընտրել «Մոդուլ»:
5. Հաջորդը կրկնակի սեղմեք մոդուլի վրա ՝ այն բացելու համար:
6. Տեղադրեք հետևյալ կոդերը մոդուլի վրա.

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Վերջապես, բայց ոչ պակաս կարևոր, կտտացրեք «Գործարկել» կոճակին կամ սեղմեք «F5»:

Դուք կստանաք նման հաղորդագրության տուփ ՝ ասելով, որ գործն ավարտված է:

Բազմաթիվ փաստաթղթերում գտեք բոլոր մեկ նախադասության պարբերությունները

1. Սկսելու համար դուք պետք է բոլոր նպատակային փաստաթղթերը տեղադրեք մեկ թղթապանակում։
2. Դրանից հետո տեղադրեք և գործարկեք հետևյալ մակրոը.

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Բաց «Փնտրել» պատուհանում ընտրեք այն թղթապանակը, որտեղ պահում եք փաստաթղթերը և կտտացրեք «Լավ»:

Դրանից հետո մակրոը կարևորում է մեկ նախադասությամբ բոլոր պարբերությունները և փաստաթղթերը բաց թողնում: Եթե ​​փաստաթուղթը չի պարունակում մեկ նախադասության պարբերություն, այն կփակվի: Բացի այդ, կա հաղորդագրության տուփ ՝ յուրաքանչյուր փաստաթղթում նշելով մեկ նախադասության պարբերությունների քանակը:

Գործ ունենալ տվյալների կորստի դեպքի հետ

Օգտագործողների սխալները և հոսանքի հանկարծակի անջատումը կարող են հանգեցնել Word- ի մարմանը: Մինչ փլուզված Բառը կարող է ոչ միայն ազդել առօրյա աշխատանքի վրա, այլև բերել դոկի վնասՍա տվյալների աղետի ամենատհաճ մասը չէ։ Ավելի լավ է անմիջապես ձեռք բերել վերականգնող ծրագիր՝ տվյալները վերականգնելու համար։

Հեղինակի ներածություն.

Վերա Չենը տվյալների վերականգնման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերականգնել գերազանցել և pdf նորոգել ծրագրային արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com