Ինչպես արագ արտահանել Outlook-ի կոնտակտային խմբի բոլոր անդամների տվյալները Excel

Լռելյայնորեն, դուք կարող եք տեսնել միայն անդամների անունները և էլփոստի հասցեները կոնտակտային խմբում: Եթե ​​ցանկանում եք ստանալ անդամների այլ մանրամասներ, կարող եք օգտագործել այս հոդվածում ներկայացված եղանակը:

Երբ կրկնակի սեղմում եք կոնտակտային խմբի վրա՝ այն բացելու համար, նրա պատուհանում կարող եք տեսնել միայն խմբի անդամների անուններն ու էլփոստի հասցեները: Դուք չեք կարող ստանալ անդամների այլ մանրամասներ, ինչպիսիք են ընկերությունը, աշխատանքի անվանումը, հեռախոսահամարը կամ բիզնեսի հասցեն և այլն: Ընդհանուր առմամբ, այս մանրամասները ստանալու համար դուք պետք է ձեռքով գտնեք անդամներին համապատասխան կոնտակտները ձեր Կոնտակտների թղթապանակում: Դա չափազանց անհանգիստ է: Այստեղ մենք ձեզ ցույց կտանք VBA կոդի մի հատված, որը կարող է արագ արտահանել այս մանրամասները Excel աշխատանքային գրքույկ:

Արտահանեք կոնտակտային խմբի բոլոր անդամների տվյալները Excel

1. Սtarգործարկել ձեր Outlook ծրագիրը:
2. Այնուհետև պետք է սեղմել «Alt + F11» ստեղնաշարի դյուրանցումները Outlook-ի հիմնական պատուհանում:
3. Հաջորդը նոր «Microsoft Visual Basic հավելվածների համար» պատուհանում դուք պետք է բացեք չօգտագործվող մոդուլ կամ ուղղակիորեն տեղադրեք նոր մոդուլ:
4. Դրանից հետո պատճենեք և տեղադրեք հետևյալ VBA կոդը այս մոդուլում:

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Դրանից հետո հարմար ստուգման համար կարող եք ավելացնել նոր VBA նախագիծը Quick Access Toolbar-ին կամ ժապավենին:
6. Ավելի ուշ սահմանեք ձեր Outlook մակրո անվտանգության մակարդակը ցածր:
7. Ի վերջո, կարող եք փորձել:

• Նախ ընտրեք կոնտակտային խումբ:
• Այնուհետև սեղմեք մակրո կոճակը Quick Access Toolbar-ում կամ ժապավենում:
• Անմիջապես մակրոն կաշխատի:
• Երբ այն ավարտվի, դուք կստանաք «Ավարտել»:
• Դրանից հետո կարող եք գնալ նախապես սահմանված նպատակակետ տեղական թղթապանակ, որտեղ կարող եք գտնել նոր Excel ֆայլ:
• Բացեք այն, կտեսնեք խմբի անդամների կոնտակտային տվյալները, ինչպես հետևյալ սքրինշոթը.

Մի խուճապի մատնվեք Outlook-ի խնդիրների առաջ

Ոչ ոք պատրաստ չէ ընդունել Outlook-ի որևէ խնդիր՝ անկախ թռուցիկ սխալի հաղորդագրությունից կամ կոռումպացված Outlook- ը տվյալների ֆայլ: Հետևաբար, օգտատերերը հակված կլինեն խուճապի մատնվել Outlook-ի խնդիրների հետ հանդիպելիս: Եթե ​​ցանկանում եք այդ դեպքում հանգստություն պահպանել, ապա պետք է երկու անհրաժեշտություն ունենաք ձեռքի տակ. Մեկը ընթացիկ Outlook տվյալների կրկնօրինակներն են: Մյուսը հզոր Outlook-ի շտկման ծրագրակազմն է, օրինակ DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերականգնում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com