Ինչպես արագ պատճենել բոլոր աղյուսակները մեկ էլփոստից մյուսը Outlook-ում

Outlook-ում, երբ դուք պետք է հանեք և պատճենեք բոլոր աղյուսակները մի էլփոստից մյուսը, դա, անկասկած, ձանձրալի և դժվար է դա անել ձեռքով: Այս հոդվածը ձեզ հետ կկիսվի շատ ավելի խելացի ճանապարհով:

Երբեմն, դուք կարող եք ցանկանալ ստեղծել նոր էլփոստ, որը պարունակում է մեկ այլ էլփոստի աղյուսակները: Եթե ​​նամակում կա միայն մեկ աղյուսակ, դա շատ հեշտ է։ Այնուամենայնիվ, եթե սկզբնաղբյուր նամակում կան բազմաթիվ աղյուսակներ, ձեռքով պատճենելը չափազանց հոգնեցուցիչ է: Այսպիսով, հաջորդում մենք կներկայացնենք մեկ այլ միջոց, որը շատ ավելի արդյունավետ և խելացի է:

Պատճենեք բոլոր աղյուսակները մեկ էլփոստից մյուսը

1. Սկզբի համար դուք պետք է ձեր Outlook-ին մուտք գործեք սովորականի պես։
2. Այնուհետև Outlook-ի հիմնական պատուհանում կարող եք սեղմել «Alt + F11» դյուրանցման ստեղները:
3. Այնուհետև «Microsoft Visual Basic հավելվածների համար» բացվող պատուհանում դուք պետք է բացեք չօգտագործված մոդուլ կամ պարզապես տեղադրեք նորը:
4. Հաջորդը, դուք կարող եք պատճենել հետևյալ VBA կոդը այս մոդուլում:

Sub CopyAllTablesFromOneEmailToAnother()
    Dim objSourceMail As Outlook.MailItem
    Dim objSourceMailDocument As Word.Document
    Dim objNewMail As Outlook.MailItem
    Dim objNewMailDocument As Word.Document
    Dim objTable As Word.Table
 
    'Get the source email
    Select Case TypeName(Application.ActiveWindow)
           Case "Explorer"
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
                objSourceMail.Display
           Case "Inspector"
                Set objSourceMail = ActiveInspector.CurrentItem
    End Select
 
    Set objSourceMailDocument = objSourceMail.GetInspector.WordEditor
 
    If objSourceMailDocument.Tables.count > 0 Then
 
       'Create a new email
       Set objNewMail = Application.CreateItem(olMailItem)
 
       For Each objTable In objSourceMailDocument.Tables
           Set objNewMailDocument = objNewMail.GetInspector.WordEditor
 
           'Copy all tables from source email to the new email
           With objNewMailDocument.Range
                .Collapse wdCollapseEnd
                .FormattedText = objTable.Range.FormattedText
                .Collapse wdCollapseEnd
                .Text = vbCrLf
           End With
      Next
 
      'Close the source email
      objSourceMail.Close olSave
      'Display the new email
      objNewMail.Display
    End If
End Sub

5. Դրանից հետո դուք կարող եք դուրս գալ ընթացիկ VBA խմբագրի պատուհանից:
6. Ավելի ուշ դուք պետք է փոխեք ձեր Outlook մակրո կարգավորումները՝ բոլոր մակրոները միացնելու համար:
7. Բացի այդ, ավելի լավ է այս մակրոն ավելացնել Quick Access Toolbar-ին, որը կարող է իրականացվել «Outlook Options»-ում:
8. Վերջապես կարող եք փորձել.

• Հենց սկզբում բացեք կամ ընտրեք նամակ, որի աղյուսակները պետք է պատճենվեն:
• Այնուհետև սեղմեք նոր ավելացված մակրո կոճակը Quick Access Toolbar-ում:
• Մակրոյի գործարկումն ավարտվելուց հետո կհայտնվի նոր էլ.

Պաշտպանեք Outlook ֆայլը կոռուպցիայի դեմ

Թեև Outlook-ը կարող է լավ դեր խաղալ անկախ էլփոստի ինքնուրույն հաճախորդից կամ անձնական գրաֆիկի կառավարիչից, այն դեռևս չի կարող զերծ մնալ սխալներից և կոռուպցիայից: Հետևաբար, ձեր Outlook-ի տվյալները պաշտպանելը, անկասկած, դժվար և հոգնեցուցիչ խնդիր է: Դուք պետք է հետևեք Outlook-ում ձեր ամենօրյա վարքագծին, օրինակ՝ մի սեղմեք կասկածելի հղումներ, ներբեռնեք ոչ անվտանգ հավելվածներ կամ սխալ փակեք Outlook-ը և այլն: Իհարկե, անհրաժեշտ է, որ մոտակայքում պահեք աստղային վերանորոգման գործիք, ինչպես, օրինակ DataNumen Outlook Repair նրանով, որ կարող է վերանորոգել Outlook- ը դժբախտությունները, ինչպես քամին:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում mdf վերանորոգում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com