Ինչպե՞ս կանխել ձեր Outlook- ում նամակների որոշակի էլեկտրոնային հասցեին ուղարկելը

Շատ օգտվողներ հույս ունեն արգելափակել Outlook- ում հատուկ էլ.փոստի հասցեին պատահաբար նամակներ ուղարկելը: Այսպիսով, այս հոդվածում մենք կներկայացնենք այն իրականացնելու մեթոդ:

Outlook-ը չի տրամադրում բնօրինակ գործառույթներ՝ որոշակի էլ.փոստի հասցեին էլ.փոստեր ուղարկելը արգելափակելու համար: Հետևաբար, եթե ցանկանում եք դա հասկանալ, անհրաժեշտ է մի փոքր սկրիպտավորում: Այժմ, ստորև, մենք կկիսվենք VBA կոդի նման մի կտորով: Եթե չգիտեք, թե ինչպես օգտագործել VBA-ն, կարող եք կարդալ նախորդ գրառումը՝ «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".

Կանխել նամակների որոշակի էլեկտրոնային հասցեին ուղարկելը

1. Սկզբում մուտք գործեք Outlook VBA խմբագիր «Alt + F11» - ի միջոցով:
2. Հետո հետևյալ կոդը տեղադրեք «ThisOutlookSession» նախագծում:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objRecipients As Outlook.Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objRecipient As Outlook.Recipient
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Expand the contact groups in Recipients
       ContactGroupFound = True
       Do While ContactGroupFound = True
          Set objRecipients = objMail.Recipients
          ContactGroupFound = False
 
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
       Loop
 
       'Remove specific email address
       For Each objRecipient In objRecipients
           If objRecipient.Address = "shelly@datanumen.com" Then
              If MsgBox("Do you want to email to " & Chr(34) & "shelly@datanumen.com" & Chr(34) & "?", vbExclamation + vbYesNo) = vbNo Then
                 objRecipient.Delete
              End If
           End If
       Next
    End If
End Sub

3. Դրանից հետո դուրս եկեք «Microsoft Visual Basic հավելվածների համար» պատուհանից:
4. Ի վերջո, փորձեք այն հետևյալ քայլերով:

• Սկսելու համար, կազմեք էլ. Նամակ և լրացրեք ստացողներին:
• Դրանից հետո կտտացրեք «Ուղարկել» կոճակին:
• Միանգամից մակրոը կաշխատի ընդլայնել ստացողների շփման խմբերը, եթե այդպիսիք կան, և պարզել, արդյոք ստացողները պարունակում են հատուկ էլ.
• Եթե ​​հասցեն գտնվի, դուք կստանաք հաղորդագրություն, ինչպես ցույց է տրված հետևյալ նկարում:
• Եթե ​​ընտրեք «Ոչ», ապա հատուկ էլփոստի հասցեն անմիջապես կջնջվի:
• Նամակն ուղարկելուց հետո կարող եք ստուգել դրա ստացողները, որոնք հաստատ չեն պարունակում հատուկ էլ. Փոստի հասցե:

Վերականգնեք ձեր կոռումպացված Outlook ֆայլը

Ձեր Outlook ֆայլը երբևէ վնասվե՞լ է։ Անկասկած, սա Outlook-ի ամենաանհանգստացնող խնդիրներից մեկն է։ Երբ դուք ենթարկվում եք դրան, դուք ստիպված եք մանիպուլյացիաներ անել։ PST- ի նորոգում, ինչը մի փոքր հանգույց է: Ինչպես միշտ, դուք կմտածեք Scanpst- ի օգտագործման մասին առաջին անգամ: Բայց, ցավոք, նման դեպքերում կարող է ձախողվել: Ձեր հանգստավայրը պետք է լինի կամ ավելի փորձառու գործիք, ինչպիսին է DataNumen Outlook Repair, կամ մասնագիտական ​​PST վերականգնման ծառայություն:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերանորոգում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com