Ինչպե՞ս սահմանել տարբեր կանխադրված հիշեցման ժամանակ տարբեր տեսակի դրոշավոր իրերի համար ձեր հայացքում

Լռելյայնորեն, Outlook- ը ավտոմատ կերպով կօգտագործի բոլոր տեսակի դրոշակավորված իրերի առաջադրանքների նախնական հիշեցման ժամանակը: Այնուամենայնիվ, եթե ցանկանում եք դրոշակավորված իրերի համար հիշեցման տարբեր ժամանակ օգտագործել ըստ իրի տեսակի, կարող եք վկայակոչել սույն հոդվածում ներկայացված մեթոդը:

Outlook- ը թույլ է տալիս սահմանել հիշեցման լռելյայն ժամանակը բոլոր դրոշավորված նյութերի համար ՝ անկախ իրի տեսակից: Կարող եք անցնել «Ֆայլ» ընտրացանկ և սեղմել «Ընտրանքներ»: Դրանից հետո, «Outlook Ընտրանքներ» պատուհանում, «Առաջադրանքներ» ներդիրում կարող եք տեսնել «Լռելյայն հիշեցման ժամանակը» տարբերակը, ինչպես ցույց է տրված հետևյալ նկարում:

Այնուամենայնիվ, օգտատերերի մեծ մասը հույս ունի օգտագործել տարբեր հիշեցման ժամեր տարբեր տեսակի դրոշակավորված տարրերի համար, ինչպիսիք են՝ «9:00»-ը՝ դրոշակավորված նամակների համար և «17:30»-ը՝ դրոշակավորված կոնտակտների համար: Այժմ, ստորև, մենք կկենտրոնանանք այս օրինակի վրա՝ մեթոդը ներկայացնելու համար:

Սահմանեք տարբեր լռելյայն հիշեցման ժամանակ `տարբեր տեսակի դրոշավոր իրերի համար

1. Սկսելու համար գործարկեք Outlook ծրագիրը:
2. Դրանից հետո մուտք գործեք Outlook VBA խմբագիր ՝ հղում կատարելով «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".
3. Հաջորդ «Microsoft Visual Basic հավելվածների համար» պատուհանում պատճենեք հետևյալ կոդը «ThisOutlookSession» նախագծում:

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Դրանից հետո վերագործարկեք Outlook-ը՝ այս մակրոն ակտիվացնելու համար։
5. Այսուհետ, ամեն անգամ, երբ նամակ եք նշում, հիշեցման ժամանակը դրոշի ամսաթվով կսահմանվի «10:00»:
6. Եվ երբ կոնտակտ եք նշում տալիս, հիշեցման ժամանակը դրոշի ամսաթվով կսահմանվի «17:30»:

Outկուն կերպով լուծել Outlook- ի խնդիրները

Դուք կարող եք հանդիպել բոլոր տեսակի խնդիրների ձեր Outlook-ում: Հետևաբար, դուք պետք է նախապես սովորեք որոշ միջոցներ դրանք լուծելու համար: Օրինակ, եթե ձեր Outlook-ը հաճախ է վերագործարկվում, դուք պետք է վերանորոգեք Office-ը կամ անջատեք երրորդ կողմի հավելումները և այլն: Կամ եթե ձեր Outlook PST-ն վարակվում է, կարող եք նախ փորձել մուտքի արկղի վերանորոգման գործիք, Երբ այն ձախողվի, կարող եք շարունակել դիմել արտաքին հզոր գործիքի, ինչպիսին է DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում mdf վերականգնում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com