Ինչպես արագ հանել բոլոր ստացողներին Outlook-ի բազմաթիվ հաղորդագրությունների (.msg) ֆայլերից

Outlook լուծումներ Սեպտեմբեր 29, 2025

Որոշ օգտատերեր կցանկանային արագորեն բոլոր ստացողներին հանել Outlook-ի էլ.փոստերից պահված բազմաթիվ Outlook հաղորդագրությունների ֆայլերից: Այժմ, այս գրառումը կանդրադառնա դրան՝ արագ մոտեցում ներկայացնելու համար:

Outlook-ի մեկ հաղորդագրության ֆայլից ստացողներին հանելու համար կարող եք պարզապես կրկնակի սեղմել այն բացելու համար, այնուհետև պատճենել ստացողներին բացված Հաղորդագրության պատուհանում: Բայց եթե Ձեզ անհրաժեշտ է գործ ունենալ Outlook-ի հաղորդագրությունների ֆայլերի խմբաքանակի հետ, ձեռնարկի մեթոդը բավականաչափ արդյունավետ չէ: Այսպիսով, դուք կարող եք շատ ավելի արդյունավետ միջոց փնտրել: Ահա այսպիսի մեկին կներկայացնենք ձեզ։ Կարդացեք դրա մանրամասները ստանալու համար:

Քաղեք բոլոր ստացողներին Outlook-ի բազմաթիվ հաղորդագրություններից (.msg) ֆայլերից

Սկսելու համար, ստացեք Outlook VBA խմբագրիչի մուտքը՝ համաձայն «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".
Հաջորդը, պատճենեք և տեղադրեք հետևյալ VBA կոդը դատարկ մոդուլի մեջ:

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

Այնուհետև տեղափոխեք կուրսորը առաջին ենթածրագրում:
Այնուհետև սեղմեք «Run» կոճակը կամ սեղմեք «F5» ստեղնը:
Այնուհետև բացվող երկխոսության վանդակում ընտրեք Windows թղթապանակը, որը պարունակում է աղբյուրի Outlook հաղորդագրության (.msg) ֆայլերը:
Ընտրելուց հետո կտտացրեք «OK»՝ թույլ տալու համար, որ մակրոները շարունակեն աշխատել:
Երբ մակրոն ավարտվի, կհայտնվի հաղորդագրություն, որը կցուցադրի արդյունահանված բոլոր ստացողների էլփոստի հասցեները, ինչպես ցույց է տրված հետևյալ սքրինշոթում:

Պաշտպանեք ձեր Outlook-ի տվյալները վտանգից

Outlook-ի տվյալները, անկասկած, հակված են կոռուպցիայի: Հետևաբար, Outlook-ի տվյալները պաշտպանելը բավականին ծանր խնդիր է: Այն պահանջում է, որ դուք համառեք Outlook-ի տվյալների կանոնավոր կրկնօրինակում ստեղծելու գործում: Նաև, հնարավորության դեպքում, խոհեմ է և խորհուրդ է տրվում պատրաստել փորձառու և պրոֆեսիոնալ Outlook PST- ի նորոգում գործիք, ինչպես DataNumen Outlook Repair, որպեսզի կարողանաք անհապաղ և ժամանակին փրկություն ստանալ Outlook-ի կոռուպցիայի դեպքում:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերականգնել Sql Server և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com