Ինչպես խմբաքանակով բացել բոլոր հիպերհղումները հատուկ տիրույթով ձեր Outlook էլ.փոստում

Երբ դիտում եք Outlook նամակ, որը պարունակում է բազմաթիվ հիպերհղումներ մարմնում, երբեմն կարող եք միայն ցանկանալ արագ բացել հիպերհղումները որոշակի տիրույթով: Այստեղ մենք կկիսվենք նման հիպերհղումներ զանգվածաբար բացելու մեթոդով:

Մեկ էլփոստի մի քանի հիպերհղումների դեպքում դուք կարող եք հույս ունենալ ստուգել դրանցից մի քանիսը, ոչ թե բոլորը: Օրինակ, դուք միայն կցանկանայիք խմբաքանակով բացել հիպերհղումները որոշակի տիրույթով: Ընդհանրապես, դրանք բացելու համար պետք է մեկ առ մեկ սեղմել։ Դա շատ անհանգիստ է։ Հետևաբար, մենք ձեզ կսովորեցնենք ավելի հարմար միջոց:

Փաթեթով բացեք բոլոր հիպերհղումները հատուկ տիրույթով էլփոստում

1. Համար, ինչպեսtart, մուտք գործել Outlook VBA խմբագիր ՝ համաձայն «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".
2. Այնուհետև «Microsoft Visual Basic հավելվածների համար» պատուհանում միացրեք «MS Word Object Lib» հղումըrary »՝ նշելով«Ինչպես ավելացնել օբյեկտ Library Հղում VBA- ում".
3. Այնուհետև պատճենեք հետևյալ VBA կոդը չօգտագործված մոդուլի կամ նախագծի մեջ:

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Հաջորդը, ավելացրեք այս մակրո Արագ մուտքի Գործիքադարակի կամ ժապավենի վրա:
5. Ի վերջո, փորձեք հետևյալ քայլերը.

• Նախ ընտրեք կամ բացեք Outlook էլ.
• Դրանից հետո կտտացրեք մակրո կոճակին:
• Միանգամից էլփոստում նախապես սահմանված տիրույթով հիպերհղումները կբացվեն Internet Explorer-ում, ինչպես ցույց է տրված հետևյալ նկարում.

Ազատվեք նյարդայնացնող հեռանկարային կոռուպցիայից

Չնայած Outlook-ը ենթակա է սխալների և կոռուպցիայի, իրականում, քանի դեռ հետևում եք բոլոր ռիսկերին, կարող եք հեշտությամբ փախչել դրանցից: Օրինակ, դուք պետք է կանոնավոր կերպով տվյալների կրկնօրինակումներ կատարեք Outlook-ի համար: Բացի այդ, դուք պետք է զգույշ լինեք կասկածելի նամակների համար, որոնք կարող են պարունակել վիրուսներ: Վերջին, բայց ոչ պակաս կարևորը, ավելի լավ է պատրաստեք Outlook- ի նորոգում օգտակար, ինչպիսիք են DataNumen Outlook Repair. Այն կարող է օգնել ձեզ Outlook-ի կոռուպցիայի դեպքում:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում կոռումպացված SQL Server և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com