Ինչպե՞ս ինքնաբերաբար օգտագործել տարբեր տառատեսակների գույներ Outlook VBA- ով նամակները պատասխանելու և փոխանցելու համար

Outlook լուծումներ Սեպտեմբեր 29, 2025
Կիսվել հիմա ՝

Լռելյայնորեն, դուք չեք կարող թույլ տալ, որ Outlook- ը ավտոմատ օգտագործի տառատեսակի տարբեր գույներ էլ-նամակները պատասխանելու և փոխանցելու համար: Հետեւաբար, եթե նման պահանջ ունեք, կարող եք կարդալ այս էջըost սովորել խելացի մոտեցում:

Outlook- ը թույլ է տալիս միայն նշել տառատեսակ, որն օգտագործվում է և՛ նամակները պատասխանելու, և՛ փոխանցելու համար: Կարող եք գնալ «Ֆայլ»> «Ընտրանքներ» բաժնում: Այնուհետև «Outlook Ընտրանքներ» բաժնում անցեք «Փոստ» ներդիրին և կտտացրեք «Գրենական պիտույքներ և տառատեսակներ.» Կոճակին: Հետագա պատուհանում դուք կարող եք տեսնել «Տառատեսակ» կոճակը «Պատասխանող կամ փոխանցող հաղորդագրություններին» բաժնում: Կտտացրեք այն, այնուհետև էլ. Նամակները պատասխանելու և փոխանցելու համար կարող եք սահմանել տառատեսակի որոշակի գույն:

Փոխեք տառատեսակը հաղորդագրությունները պատասխանելու կամ վերահասցեավորելու հարցում

Այնուամենայնիվ, շատ օգտվողներ հույս ունեն տառատեսակների տարբեր գույներ օգտագործել էլ-նամակները պատասխանելու կամ փոխանցելու համար: Չնայած Outlook- ը դրա համար ոչ մի ուղղակի առանձնահատկություն չի տրամադրում, այն դեռ կարող է իրականացվել VBA կոդի միջոցով: Այժմ կարդացեք VBA կոդի նման կտոր ստանալու համար:

Ավտոմատ օգտագործեք տառատեսակների տարբեր գույներ էլ-նամակները պատասխանելու և փոխանցելու համար

  1. Համար, ինչպեսtart, գործարկել Outlook ծրագիրը:
  2. Ապա, գործարկեք VBA խմբագիրը ՝ հղում կատարելով «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".
  3. Հաջորդը, համաձայն «Ինչպես ավելացնել օբյեկտ Library Հղում VBA- ում«, Ավելացնել հղումը« MS Word Object Library ”:
  4. Դրանից հետո պատճենեք հետևյալ կոդը «ThisOutlookSession» նախագծում:
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

VBA կոդ - Էլեկտրոնային նամակները պատասխանելու և փոխանցելու համար ավտոմատ օգտագործեք տառատեսակի տարբեր գույներ

  1. Դրանից հետո ռեսtart Outlook ՝ այս մակրոը ակտիվացնելու համար:
  2. Վերջապես, կարող եք փորձել:
  • Ընտրեք կամ բացեք էլ.
  • Դրանից հետո կտտացրեք «Պատասխանել» կոճակին: Պատասխանելով էլ. Փոստին ՝ կարող եք մարմնում մուտքագրել որոշ բառեր: Տառատեսակի գույնը պետք է լինի վարդագույն:«Վարդագույն» տառատեսակը «Պատասխանել» -ում
  • Կամ կտտացրեք «Պատասխանել բոլորին» կոճակին: Նոր «պատասխանող բոլոր» նամակում մուտքագրեք բառերը մարմնում: Տառատեսակի գույնը, անշուշտ, կանաչ է:«Կանաչ» տառատեսակը «Պատասխանել բոլորին» բաժնում
  • Նմանապես, կտտացրեք «Փոխանցել» կոճակին: Փոխանցման նամակում նոր բառերը կցուցադրվեն կապույտով:«Կապույտ» տառատեսակը «Փոխանցել» -ում

Օգտվեք վստահելի ծրագրակազմից

Դեպքում Հեռանկարային կոռուպցիա, մost օգտվողները հակված են դիմել Outlook- ի վերականգնման ծրագրակազմին: Շուկայում առկա են մեծ թվով այդպիսի ծրագրեր: Եվ նրանցից ոմանք նույնիսկ անվճար են: Այնուամենայնիվ, դուք պետք է զգուշանաք անհայտ աղբյուրներից եկածներից, քանի որ դրանք կարող են ավելի ու ավելի վատացնել ընթացիկ դեպքը: Դուք պետք է օգնություն ցուցաբերեք հուսալի և փորձառու գործիքի նման DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում կոռումպացված sql և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: