Ինչպե՞ս հատուկ օրերից հետո ավտոմատ կերպով ջնջել Outlook- ի էլփոստերը հատուկ ուղարկողից

Որպեսզի ձեր Outlook- ը ավտոմատ կերպով ջնջի նամակները որոշակի ուղարկողից որոշակի օրերից, կարող եք կարդալ այս հոդվածը: Այստեղ մենք ձեզ ցույց կտանք VBA կոդն օգտագործելու մանրամասն քայլերը ՝ այն ստանալու համար:

Երբ խոսքը վերաբերում է էլփոստի ավտոմատ ջնջմանը, նախ կարող եք մտածել «AutoArchive» հատկության մասին: Այնուամենայնիվ, այն չի կարող զտել հատուկ ուղարկողներին էլեկտրոնային փոստի ավտոմատ արխիվացման ժամանակ: Հետեւաբար, օրինակ, եթե ցանկանում եք x հաղորդագրությունից հետո ավտոմատ կերպով ջնջել նամակները որոշակի ուղարկողից, ապա պետք է օգտագործեք այլ միջոցներ, ինչպիսիք են հետևյալը:

X- ից հետո ավտոմատ ջնջեք էլփոստերը որոշակի ուղարկողից

1. Սկզբում գործարկեք ձեր Outlook ծրագիրը։
2. Ապա, գործարկեք Outlook VBA խմբագիրը ՝ համաձայն «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".
3. Հաջորդը, պատճենեք հետևյալ VBA կոդը «ThisOutlookSession» նախագծում:

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Դրանից հետո վերագործարկեք Outlook-ը՝ այս մակրոն ակտիվացնելու համար։
5. Այդ ժամանակից ի վեր, ամեն անգամ, երբ կոնկրետ ուղարկողի կողմից նոր նամակ է գալիս մուտքի արկղ, այն նշանակվելու է որոշակի պիտանելիության ժամկետով ՝ այն ստանալուց հետո կոնկրետ օրեր:
6. Այնուհետև, ամեն անգամ, երբ դուք գործարկում եք Outlook-ը, Outlook-ը ավտոմատ կերպով կստուգի և կջնջի ժամկետանց նամակները տվյալ ուղարկողից։

Վերականգնել Outlook- ի տվյալները կոռուպցիայից հետո

Միգուցե Outlook- ում բախվել եք տարբեր սխալների և խնդիրների: Հետևաբար, երբևէ բախվե՞լ եք Outlook- ի կոռուպցիայի հետ: Օրինակ, եթե դուք հաճախ անպատշաճ կերպով դուրս եք գալիս Outlook- ից, ձեր PST ֆայլը հակված է վնասվելու: Ընդհանրապես, նման դեպքում դուք կարող եք ընտրել Outlook- ի տվյալների պահուստավորումից հետ վերցնելու համար: Կամ կարող եք կամ օգտագործել մուտքի արկղի վերանորոգման գործիք կամ հուսալի արտաքին գործիք, ինչպիսիք են DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերականգնել sql և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com