Outlook- ի կոնտակտային խմբի բոլոր անդամներին Excel- ին արտահանելու 2 մեթոդ

Outlook լուծումներ Սեպտեմբեր 29, 2025

Timesամանակ առ ժամանակ դուք կարող եք արտահանել անդամներին որոշակի Outlook կոնտակտային խմբում: Այսպիսով, այս հոդվածը ձեզ կկիսվի 2 միջոց ՝ խմբի անդամներին Excel- ում հանելու համար:

Outlook- ն առաջարկում է հարազատ հատկություն, որը թույլ է տալիս Ձեզ արտահանել որոշակի կոնտակտային պանակի բոլոր կոնտակտները: Այնուամենայնիվ, դա ձեզ թույլ չի տալիս արտահանել կոնտակտային խմբեր, էլ չեմ ասում կապի խմբերում անդամներին հանելու մասին: Հետեւաբար, եթե ցանկանում եք արդյունահանել ընտրված կոնտակտային խմբի անդամներին, ապա ձեզ հարկավոր է ևս մի քանի ջանք գործադրել: Ահա երկու խորհուրդ, որոնց կարող եք վկայակոչել:

Մեթոդ 1. Խմբի անդամներին հանեք Save As- ի միջոցով

Հենց սկզբից գործարկեք Outlook- ը:
Դրանից հետո գտեք և ընտրեք այն կոնտակտային խումբը, որի անդամները պետք է արդյունահանեք:
Հաջորդը պետք է գնաք «Պատկեր» ընտրացանկ և սեղմեք «Պահել որպես»:
Հետևաբար, «Պահել As» երկխոսության պատուհանում ընտրեք նպատակակետի պահոց ՝ պահելու համար և «Save as type» ցանկի բաց բաժնից ընտրեք «Only Text»:
Դրանից հետո կտտացրեք «Պահել» կոճակին:
Դրանից հետո բացեք Excel- ը և ստեղծեք նոր Excel ֆայլ:
Ավելի ուշ դուք պետք է դիմեք «Պատկեր» կոճակին և կտտացրեք «Բացել» կոճակին:
Հաջորդ «Բաց» երկխոսության դաշտում նախ պետք է մուտք գործեք այն թղթապանակ, որտեղ հենց հիմա պահպանել եք կոնտակտների խումբը:
Դրանից հետո կտտացրեք «Ֆայլի անունը» տողի երկրորդ տուփին և իր ցուցիչից ընտրեք «Բոլոր ֆայլերը»:
Դրանից հետո կոնտակտային խմբի համար սեղմեք տեքստային ֆայլը և սեղմեք «Բաց»:
«Տեքստի ներմուծման մոգ» պատուհանի պատուհանի պատուհանում համոզվեք, որ ընտրված է «Սահմանազատված» -ը և կտտացրեք «Ավարտել» կոճակին:
Վերջապես, դուք կստանաք անդամներին, ինչպես հետևյալ սքրինշոթը.

Մեթոդ 2. Խմբի անդամներին հանեք Outlook VBA- ի միջոցով

Առաջին հերթին, Outlook- ում սեղմեք «Alt + F11» ստեղնային կոճակները:
Դրանից հետո բացեք նոր մոդուլ VBA խմբագրի պատուհանում:
Դրանից հետո պատճենեք հետևյալ VBA կոդերը դրանում:

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

Դրանից հետո դուք կարող եք սովորույթը սովորաբար ավելացնել Macro- ի Արագ մուտքի գործիքագոտում (QAT):
Ավելի ուշ, դուք կարող եք ընտրել կապի խումբ և սեղմել մակրո կոճակին QAT- ում:
Արտահանումից հետո դուք կստանաք հաղորդագրություն. «Արտահանումն ավարտված է»:
Ի վերջո, դուք կարող եք գտնել Excel ֆայլը թղթապանակում, որը կանխորոշված է VBA կոդերում: Բացեք այն, կարող եք տեսնել խմբի անդամներին, ինչպես ստորև նշված պատկերն է.

Վերադարձեք ձեր նախորդ PST տվյալները

Քանի որ Outlook- ը ենթակա է վթարի, ձեր PST տվյալները կարող են փչանալ առանց նախանշանների: Հետեւաբար, դուք պետք է պարբերաբար կրկնօրինակեք ձեր PST ֆայլերը: Բացի այդ, դուք ավելի լավ կլիներ պատրաստել այնպիսի հզոր գործիք, ինչպիսին է DataNumen Outlook Repair, որը կարող է վերանորոգել Outlook- ը ժամանակին տրված տվյալները:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում ֆիքսել sql և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com