Ինչպես արտահանել ձեր մուտքի հաշվետվությունը ա PDF Ֆայլ VBA-ի միջոցով

Մուտքի լուծումներ Սեպտեմբեր 29, 2025
Կիսվել հիմա ՝

Իմացեք, թե ինչպես կարող եք ստեղծել VBA ֆունկցիա, որը թույլ կտա պահպանել ձեր Access Report-ը որպես PDF ընդամենը մեկ կոճակի սեղմումով: Կարիք չկա ամեն անգամ գնալ Access Ribbon-ին:

Մուտքի հաշվետվությունները կարող են ձեռքով պահպանվել որպես PDF ֆայլ. Ձեզ մնում է միայն.Ձեռքով պահված է որպես PDF Ֆայլ

  1. Բացեք զեկույցը:
  2. Գնացեք մուտքի ժապավեն. Արտաքին տվյալներ > PDF կամ XPS.
  3. Ընտրեք ֆայլի անունը և թղթապանակի ուղին, որտեղ ցանկանում եք, որ այն պահպանվի:
  4. Սեղմեք Հրապարակել և վերջ:

Հեշտ, չէ՞: Այնուամենայնիվ, եթե ձեզ համար անհրաժեշտություն կա մի քանի անգամ արտահանել հաշվետվություններ, ասենք օրական կտրվածքով, դա կարող է լինել մի փոքր հարկվող:

Մի անհանգստացեք: Ավելի հեշտ ճանապարհ կա. Կոճակի ընդամենը մեկ սեղմումով ձեր զեկույցը կարող է անմիջապես արտահանվել ձեր նշանակված թղթապանակ: Դա կարելի է անել VBA-ի օգնությամբ: Պարզապես հետևեք ստորև նշված քայլերին:

Download Now

Եթե ​​ցանկանում եք հնարավորինս շուտ սկսել օգտագործել գործառույթը, ապա կարող եք՝

Ներբեռնեք Նմուշի շտեմարանը VBA կոդերով հիմա

Հակառակ դեպքում, եթե ցանկանում եք ինքնուրույն վարվել, կարող եք կարդալ ստորև բերված բովանդակությունը:

VBA գործառույթ ստեղծելու քայլեր, որը պահպանում է մուտքի հաշվետվությունը որպես PDF Ֆայլ

1. Ավելացնել հրամանի կոճակ ձեր զեկույցի ներսում

Այս հոդվածը ենթադրում է, որ դուք արդեն ստեղծել եք Մուտքի հաշվետվություն: Բացեք այն դիզայնի տեսքով և ավելացրեք կոճակը Հաշվետվության վերնագրում (ինչպես ցույց է տրված ստորև):Ավելացնել հրամանի կոճակ ձեր հաշվետվության մեջ

Վերանվանել կոճակը որպես cmd_exportPDF, Անել դա:

  1. Դիզայնի տեսանկյունից ընտրեք կոճակը:
  2. Բացեք Հատկությունների թերթիկը (ALT + Enter):
  3. Գնացեք Այլ ներդիր > Անուն:
  4. Փոխեք անվան արժեքը cmd_exportPDF-ի։

2. Ավելացնել կոդ հրամանի կոճակի համար

Կոդն ավելացնելու համար նախ պետք է կոճակին ավելացնել On Click իրադարձությունը:

  1. Ընտրված հրամանի կոճակով նորից գնացեք Հատկությունների թերթիկ:
  2. Կտտացրեք «Իրադարձություն» ներդիրին:
  3. Փնտրեք On Click և ընտրեք…
  4. Երբ Ընտրեք Builder ընտրացանկը բացվում է, ընտրեք Code Builder և սեղմեք OK:
  5. Սա կբացի VBA խմբագիրը:

Այժմ պատճենեք ստորև նշված կոդը:

Մի մոռացեք թարմացնել ֆայլի անվան և fldrPath-ի արժեքները: Մեկնաբանությունների բաժնում նրանցից յուրաքանչյուրն ունի աստղանիշ (*):

Function FileExist(FileFullPath As String) As Boolean
  Dim value As Boolean
  value = False
  If Dir(FileFullPath) <> "" Then
    value = True
  End If
  FileExist = value
End Function

Private Sub cmd_exportPDF_Click()
 
  Dim fileName As String, fldrPath As String, filePath As String
  Dim answer As Integer
 
  fileName = "Member Contact Details" 'filename for PDF file*
  fldrPath = "C:\Users\Jessica\Desktop\PDF Exports" 'folder path where pdf file will be saved *
 
  filePath = fldrPath & "\" & fileName & ".pdf"
 
  'check if file already exists
  If FileExist(filePath) Then
    answer = MsgBox(prompt:="PDF file already exists: " & vbNewLine & filePath & vbNewLine & vbNewLine & _
      "Would you like to replace existing file?", buttons:=vbYesNo, Title:="Existing PDF File")
    If answer = vbNo Then Exit Sub
  End If
 
  On Error GoTo invalidFolderPath
  DoCmd.OutputTo objecttype:=acOutputReport, objectName:=Me.Name, outputformat:=acFormatPDF, outputFile:=filePath
 
  MsgBox prompt:="PDF File exported to: " & vbNewLine & filePath, buttons:=vbInformation, Title:="Report Exported as PDF"
  Exit Sub
 
  invalidFolderPath:
  MsgBox prompt:="Error: Invalid folder path. Please update code.", buttons:=vbCritical
 
End Sub

Կոդի այս տողերը կլինեն.

  1. Նախ ստուգեք, արդյոք ա PDF նույն ֆայլի անունով ֆայլ արդեն գոյություն ունի նշված թղթապանակում: Եթե ​​դա տեղի ունենա, հուշում կհայտնվի, որում հարցնում եք, թե արդյոք ցանկանում եք այն փոխարինել նորով:

Եթե ​​ընտրեք «այո», հաշվետվությունը կշարունակվի արտահանման գործընթացով։ Հակառակ դեպքում ֆայլը չի ​​փոխարկվի PDF-ի։

  1. Եթե ​​դուք մուտքագրել եք թղթապանակի ուղին, որը գոյություն չունի, հուշում կհայտնվի՝ խնդրելով թարմացնել կոդում նշված թղթապանակի ուղին: Արտահանման գործընթացը չի շարունակվի, քանի դեռ դա չի ուղղվել:
  2. Զեկույցը հաջողությամբ արտահանվելուց հետո կհայտնվի հուշում, որը ցույց է տալիս, թե որտեղ է PDF ֆայլը պահպանվել է:

Վե՛րջ: Այժմ ժամանակն է փորձարկել ձեր կոճակը:

Հնարավոր չէ բացել Access Database-ը

Ամենասարսափելի բանը, որ կարող է պատահել ցանկացած Access օգտատիրոջ հետ, մի օր արթնանալն ու հասկանալն է, որ տվյալների բազան այլևս հնարավոր չէ բացել։ Այն վնասվել է։ Ավելի վատն այն է, որ դուք հասկանում եք, որ չեք կարողացել պահուստավորել ձեր տվյալները։ Մի անհանգստացեք։ DataNumen Inc.-ն ստեղծել է ծրագրակազմ, որը կարող է ամրագրել Access- ը տվյալների բազա։ Ձեր տվյալների բազան դեռ կարող է կյանքի կոչվել:

Հեղինակի ներածություն.

Jayme Stack- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերականգնում և գերազանցել վերականգնման ծրագրային արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: