Ինչպես խմբաքանակով արտահանել բազմաթիվ Outlook նամակներ մեկ բառի փաստաթղթի մեջ VBA-ի միջոցով

Outlook լուծումներ Սեպտեմբեր 29, 2025
Կիսվել հիմա ՝

Եթե ​​ցանկանում եք խմբաքանակով արտահանել մի քանի Outlook նամակներ մեկ բառային փաստաթղթի մեջ, կարող եք օգտագործել այս հոդվածում ներկայացված VBA կոդը: Այն կարող է օգնել ձեզ կատարել այս խնդիրը վայրկյանների ընթացքում:

Ես երբևէ ներկայացրել եմ, թե ինչպես փոխարկել Outlook նամակը Word փաստաթղթի իմ նախորդ հոդվածում.Outlook-ի էլփոստը Word փաստաթղթի փոխարկելու 2 արդյունավետ մեթոդ»: Սակայն այդ պ.-ում նշված և՛ 2 միջոցներըost անօգնական կլինի այն դեպքում, երբ դուք ցանկանում եք խմբաքանակով արտահանել բազմաթիվ նամակներ մեկ Word փաստաթղթում: Այսպիսով, այստեղ մենք ձեզ կսովորեցնենք մեկ այլ ճանապարհ: Այժմ կարդացեք այն մանրամասնորեն ստանալու համար:

Բազմաթիվ Outlook նամակների խմբաքանակի արտահանում մեկ բառի փաստաթղթի մեջ VBA-ի միջոցով

Բազմաթիվ Outlook նամակների խմբաքանակի արտահանում մեկ բառի փաստաթղթի մեջ

  1. Սtarգործարկել ձեր Outlook ծրագիրը:
  2. Այնուհետև Outlook-ի հիմնական պատուհան մուտք գործելուց հետո անհրաժեշտ է սեղմել «Alt + F11» կոճակները:
  3. Հաջորդը դուք մուտք կունենաք Outlook VBA խմբագրիչ, որտեղ դուք պետք է բացեք դատարկ մոդուլ:
  4. Այնուհետև պատճենեք ստորև ներկայացված VBA կոդը բացված մոդուլի պատուհանում:
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA Code - Բազմաթիվ Outlook նամակների խմբաքանակի արտահանում մեկ բառի փաստաթղթի մեջ

  1. Դրանից հետո ավելի լավ է այս նոր VBA նախագիծն ավելացնեք Quick Access Toolbar-ին կամ ժապավենին:
  2. Ի վերջո, կարող եք փորձել:
  • Սկզբում ընտրեք մի քանի Outlook էլ.
  • Այնուհետև գտնեք և սեղմեք նոր ավելացված մակրո կոճակը:
  • Այն բանից հետո, երբ ձեզ կառաջարկվի «Ավարտել», կարող եք թերթել նախապես սահմանված տեղական թղթապանակը՝ նոր Word փաստաթուղթ գտնելու համար:
  • Բացեք այս փաստաթուղթը, որում դուք կարող եք տեսնել, որ ընտրված բոլոր նամակները արտահանվել են:

Մոտակայքում պահեք հզոր վերականգնման գործիք

Անկախ բազմաթիվ գործառույթներից, Outlook-ը դեռևս չի կարող զերծ մնալ սխալներից: Եթե ​​դուք սովոր եք մենակ թողնել սխալները, երբ դրանք կուտակվում են, Outlook-ի վթարը անպայման տեղի կունենա: Այդ պահին անհրաժեշտ է կրկին դիմել վերականգնման հզոր և արդյունավետ գործիքին, օրինակ DataNumen Outlook Repair, Դա լավատեղյակ է PST շտկում. Քանի դեռ դրա հետ դուք այլևս կարիք չեք ունենա մտահոգվելու հեռանկարային տվյալների կորստով:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում կոռումպացված mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: