Ինչպես ավտոմատ սահմանել տարբեր հիշեցումների ժամանակ Outlook-ի հանդիպումների համար տարբեր գույների կատեգորիաներով

Եթե ​​դուք դասակարգում եք Outlook-ի հանդիպումներն ըստ գունային կատեգորիաների և ցանկանում եք տարբեր գունային կատեգորիաների հանդիպումների համար տարբեր հիշեցումների ժամանակ սահմանել, կարող եք անդրադառնալ այս հոդվածին: Այստեղ մենք ձեզ կսովորեցնենք այն իրականացնել Outlook VBA-ով:

Օրինակ, դուք հանդիպումները բաժանում եք երկու խմբի։ Մեկը «Տեղից դուրս» գունային կատեգորիայի մեջ է, քանի որ հանդիպման վայրը չափազանց հեռու է, իսկ մյուսը՝ «Տեղում» գունային կատեգորիայի մեջ, քանի որ հանդիպման վայրը հենց այստեղ է։ Այժմ դուք ցանկանում եք, որ Outlook-ը կարողանա ավտոմատ կերպով սահմանել «տեղից դուրս» հանդիպման հիշեցման ժամը՝ որպես մեկնարկից 1 ժամ առաջ, իսկ «տեղում» հանդիպմանը՝ որպես մեկնարկից 15 րոպե առաջ։ Հաշվի առնելով այս պահանջը՝ այսուհետ մենք կներկայացնենք մի արագ մեթոդ։

Ավտոմատ սահմանել տարբեր հիշեցումներ տարբեր գույների կատեգորիաների հանդիպումների համար

1. Սկսելու համար գործարկեք ձեր Outlook ծրագիրը:
2. Այնուհետև սեղմեք «Alt + F11» կոճակները՝ VBA խմբագրիչի պատուհանին մուտք գործելու համար:
3. Հաջորդ պատուհանում պատճենեք և տեղադրեք ներքևում գտնվող VBA կոդը «ThisOutlookSession» նախագծում:

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Ավելի ուշ, այս մակրոն գործարկելու համար անհրաժեշտ է սեղմել «Application_Startup» ենթածրագիրը և սեղմել «F5» ստեղնը։
5. Այդ ժամանակից ի վեր, ամեն անգամ, երբ նոր հանդիպում ավելացվում է լռելյայն օրացույցին կամ փոխում եք գոյություն ունեցող հանդիպումը, Outlook-ը ավտոմատ կերպով կստուգի հանդիպման կատեգորիաները և ավտոմատ կերպով կսահմանի տարբեր հիշեցումների ժամանակը:

Վերացնել Outlook- ի սխալները

Ժամանակ առ ժամանակ Outlook-ում կարող են առաջանալ տարբեր խնդիրներ: Հետևաբար, չափազանց կարևոր է, որ օգտատերերը սովորեն, թե ինչպես հաղթահարել Outlook-ի խնդիրները: Սկսելու համար ավելի լավ է պարբերաբար պահուստավորել Outlook-ի տվյալները: Ավելին, եթե մատչելի է, խորհուրդ է տրվում պահպանել հզոր... Outlook- ի նորոգում մոտակայքում գտնվող գործիք, ինչպիսիք են DataNumen Outlook Repair. Այն կարող է սկանավորել ձեր PST ֆայլը՝ Outlook-ի խնդիրները պարզելու և այնուհետև դրանք հեշտությամբ լուծելու համար:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերականգնում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com