Բազմաթիվ Word փաստաթղթերը մեկի մեջ արագ միավորելու 2 եղանակ VBA-ի միջոցով

Այս հոդվածում մենք ուրախ ենք կիսվել ձեզ հետ VBA-ի միջոցով բազմաթիվ Word փաստաթղթերը մեկի մեջ արագ միացնելու 2 եղանակով:

Word-ում կա լռելյայն ներկառուցված հատկություն, որն օգնում է օգտվողին միավորել կամ միավորել մի քանի փաստաթղթեր մեկի մեջ: Մանրամասները բացատրվում են այս հոդվածում. Ինչպես միավորել և միավորել բազմաթիվ բառերի փաստաթղթերը մեկի մեջ

Այդ մեթոդով դուք պետք է մի քանի կտտոց կատարեք, և հաջորդ փաստաթղթի բովանդակությունը միշտ գալիս է նախորդից անմիջապես հետո: Ուստի մենք ցանկանում ենք ձեզ առաջարկել դա անելու ավելի արագ ուղիներ:

Մեթոդ 1. Միավորել ընտրված փաստաթղթերը մեկի մեջ

1. Նախ և առաջ, ստեղծեք նոր դատարկ փաստաթուղթ։
2. Միացրեք VBA խմբագրիչը Word-ում՝ սեղմելով «Alt+ F11»:
3. Հաջորդը կտտացրեք «Նորմալ» կետին:
4. Դրանից հետո կտտացրեք «Տեղադրել» կետին:
5. Եվ ընտրեք «Մոդուլ» -ը:
6. Կրկնակի սեղմեք նոր մոդուլի վրա՝ խմբագրման տարածքը բացելու համար:
7. Տեղադրեք հետևյալ մակրոը ՝

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Հաջորդը սեղմեք «Run» կամ սեղմեք «F5»:
9. Այժմ «Browse» պատուհանում ընտրեք մի քանի ֆայլ՝ սեղմելով «Ctrl» և սեղմեք «OK»:
10. Այնուհետև ընտրված ֆայլերի բոլոր պարունակությունները կմիավորվեն նոր փաստաթղթում, որտեղ յուրաքանչյուր փաստաթղթի տեքստը կսկսվի նոր էջից։

Նշում:

Ինչպես նշեցինք, այս մակրոն յուրաքանչյուր փաստաթղթի տեքստերը տեղադրում է նոր էջում։ Բայց եթե ձեզ հարկավոր է, որ դրանք լինեն մեկը մյուսի հետևից, կարող եք փոխել որոշ կոդային տողեր մակրոյում: Պարզապես գտեք «If nEachSelectedFile < nTotalFiles Then» տողը, ջնջեք այն և հաջորդ վեց տողերը նույնպես:

Մեթոդ 2. Միավորել բոլոր փաստաթղթերը թղթապանակում մեկում

Եթե ​​դուք ունեք ֆայլերի թղթապանակ, որը պետք է համակցվի, ապա այս մակրոն գեղեցիկ կաշխատի:

1. Սկսելու համար տեղադրեք և գործարկեք մակրոն, ինչպես նկարագրված է 1-ին մեթոդում։
2. Դրանից հետո մակրոն փոխարինեք այսով.

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Գործարկեք մակրոն՝ սեղմելով «Գործարկել»:
4. Հաջորդը տեսնում եք «Թերթել» պատուհանը բացված: Ընտրեք այն թղթապանակը, որտեղ դուք պահում եք բոլոր փաստաթղթերը: Եվ սեղմեք «OK»:

Նմանապես, յուրաքանչյուր փաստաթղթի տեքստը սկսվում է նոր էջից: Որպեսզի դրանք մեկը մյուսի հետևից կպչեն, գտեք և ջնջեք «.InsertBreak Type:=wdPageBreak» կոդային տողը:

Պատշաճ կերպով պաշտպանեք ձեր Word փաստաթուղթը

Ձեր Word փաստաթղթերը պաշտպանելու լավագույն միջոցներից մեկը դրանք կանոնավոր կերպով կրկնօրինակելն է: Պահուստային պատճենները ձեռքին, դուք երբեք ստիպված չեք լինի վախենալ տվյալների կորստից: Բացի այդ, խորհուրդ է տրվում նաև գործիք ձեռք բերել վերանորոգման docx եթե դրանցից որևէ մեկը վնասվելու է:

Հեղինակի ներածություն.

Վերա Չենը տվյալների վերականգնման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վնասված Excel- ը և pdf նորոգել ծրագրային արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com