Ձեր Word- ում հատուկ տեքստ պարունակող նախադասությունները գտնելու կամ ջնջելու 2 արագ եղանակ

Այս հոդվածում մենք ձեզ կառաջարկենք 2 արագ եղանակ՝ ձեր Word-ում կոնկրետ տեքստ պարունակող նախադասություններ գտնելու կամ ջնջելու համար։

Բոլորին հայտնի է, որ մենք կարող ենք օգտագործել Word-ի «Գտնել և փոխարինել» ֆունկցիան՝ որոշակի բառերի բոլոր հանդիպումները հեշտությամբ գտնելու համար։ Այդ դեպքում մենք խնդիր չենք ունենա դրանք ընդգծելու, փոխարինելու կամ հեռացնելու հարցում։ Ինչպես տեսնում եք, թիրախը բառ կամ արտահայտություն է։ Այսօր, սակայն, մենք ուրախ ենք ձեզ ներկայացնել որոշակի տեքստ պարունակող նախադասություններ գտնելու կամ ջնջելու մակրո եղանակը։

Մեթոդ 1. Գտեք կամ ջնջեք հատուկ տեքստ պարունակող նախադասություններ

1. Սկսելու համար սեղմեք «Alt + F11» ՝ Word- ում VBA- ի խմբագրիչը գործարկելու համար:
2. Հաջորդը ստեղծեք նոր մոդուլ՝ սեղմելով «Նորմալ»:
3. Այնուհետև կտտացրեք «Տեղադրեք» և ընտրեք «Մոդուլ»՝ նորը ստանալու համար:
4. Եվ բացեք մոդուլը կրկնակի սեղմումով:
5. Այժմ տեղադրեք հետևյալ կոդերը.

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Հաջորդը կտտացրեք «Գործարկել»:
7. Կլինի մուտքագրման տուփ, որը կխնդրի ձեզ մուտքագրել տեքստ: Պարզապես մուտքագրեք ընդհանուր տեքստը, որը պարունակում է բոլոր նախադասությունները: Սեղմեք «OK»:
8. Այնուհետև կտեսնեք ընտրված տեքստը պարունակող նախադասություն, որը հուշում է հաղորդագրության տուփով: Սեղմեք «Այո»՝ նախադասությունը ջնջելու համար, իսկ «Ոչ»՝ այն պահպանելու համար:
9. Հաստատումից հետո ընտրության մեջ է հաջորդ նախադասությունը՝ նշանակված տեքստով։ Եվ կա նաև հաստատման վանդակը։ Այսինքն՝ մակրոն ձեզ քայլ առ քայլ տանում է ամբողջ փաստաթղթով՝ գտնելով թիրախային նախադասությունները և ամեն անգամ հարցնելով ձեր հաստատումը։

Մեթոդ 2. Գտեք կամ ջնջեք ցանկի ցանկացած տեքստ պարունակող նախադասություններ

1-ին մեթոդի մակրոյով դուք կարող եք որոնել միայն մեկ բառ կամ արտահայտություն մեկ անգամ: Իհարկե, դուք կարող եք մի քանի անգամ գործարկել մակրո՝ բառերի կամ արտահայտությունների բազմաթիվ օրինակներ գտնելու համար: Բազմակի որոնման կարիքը բավարարելու համար մենք ձեզ կտրամադրենք ևս մեկ մակրո:

1. Սկզբում բոլոր թիրախային տեքստերը տեղադրեք նոր փաստաթղթի մեջ։ Համոզվեք, որ տեքստի յուրաքանչյուր հատված զբաղեցնում է մեկ պարբերություն՝ առանց վերջնամասի։ Փակեք և պահպանեք փաստաթուղթը։
2. Հաջորդը տեղադրեք և գործարկեք մակրո՝ 1-ին մեթոդի ճշգրիտ քայլերով:
3. Դրանից հետո մակրոն փոխարինեք այսով.

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Այժմ կբացվի «Փնտրել» պատուհանը: Ընտրեք նոր պահված փաստաթուղթը և սեղմեք «Բացել»:
5. Հետևյալ ընթացակարգը նույնն է, ինչ 1-ին մեթոդով:

Կոռումպացված փաստաթղթերի դեմ պայքարի մոտեցում

Արժեքավոր տվյալների կորուստը բացարձակապես կործանարար է: Դա կարող է նույնիսկ վտանգված թողնել ձեր բիզնեսը: Նման հիասթափությունից խուսափելու համար դուք պետք է ձեռք բերեք a Բառի ուղղում գործիք որքան հնարավոր է շուտ: Նման գործիքը կօգնի ձեզ հաղթել փաստաթղթերի կոռուպցիայի դեմ պայքարում:

Հեղինակի ներածություն.

Վերա Չենը տվյալների վերականգնման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում ուղղել Excel- ը և pdf նորոգել ծրագրային արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com