Excel- ի աշխատաթերթում ընտրված բջիջներն արագ ուղարկելու 2 եղանակ ՝ որպես Outlook էլփոստ

Երբեմն, գուցե ցանկանաք արագորեն զետեղել ընտրված բջիջները Excel-ի աշխատաթերթում Outlook-ի նամակում և ուղարկել այս նամակը: Այս հոդվածը կանդրադառնա այս ցանկությունին՝ ձեզ 2 մեթոդ առաջարկելու համար։

Իմ նախորդ հոդվածը «Excel- ի աշխատանքային էջը որպես Outlook էլփոստ ուղարկելու 2 արագ մեթոդ” սովորեցրել է ձեզ, թե ինչպես ուղարկել Excel-ի ամբողջ աշխատաթերթը որպես էլ. Այնուամենայնիվ, երբեմն, դուք ցանկանում եք ուղարկել ընտրված բջիջները աշխատաթերթում միայն որպես էլ. Ի պատասխան այս պահանջի՝ այստեղ մենք ձեզ կբացահայտենք 2 մեթոդ։ Դուք կարող եք ընտրել կամ ըստ ձեր նախասիրության:

Մեթոդ 1. Պատճենեք ընտրված բջիջները էլփոստին ձեռքով

1. Սtart-ով, բացեք սկզբնաղբյուր Excel ֆայլը և մուտք գործեք ճիշտ Excel աշխատաթերթը:
2. Այնուհետև ընտրեք այն բջիջները, որոնք ցանկանում եք ուղարկել որպես Outlook էլ.
3. Հաջորդը սեղմեք «Ctrl + C» ստեղնաշարի դյուրանցումները՝ ընտրված բջիջները պատճենելու համար:
4. Դրանից հետո գործարկեք ձեր Outlook հավելվածը:
5. Այնուհետև կտտացրեք «Նոր էլփոստ» կոճակը «Տուն» ժապավենի վրա՝ նոր Outlook էլ.
6. Ավելի ուշ նոր Հաղորդագրության պատուհանում սեղմեք հաղորդագրության հիմնական բաժինը:
7. Այնուհետև սեղմեք «Ctrl + V» կոճակները՝ նախկինում պատճենված ընտրված Excel բջիջները տեղադրելու համար:
8. Վերջապես, դուք կարող եք գրել նամակը, ինչպես միշտ և սեղմել «Ուղարկել» կոճակը՝ այն ուղարկելու համար:

Մեթոդ 2. ուղարկեք ընտրված բջիջները որպես էլ.փոստ VBA-ի միջոցով

1. Հենց սկզբում բացեք Excel-ի աղբյուրի աշխատանքային գիրքը:
2. Այնուհետև սեղմեք «Alt + F11» կոճակները՝ Excel VBA խմբագրին մուտք գործելու համար:
3. Նոր պատուհանում սեղմեք «Տեղադրել» > «Մոդուլ»՝ նոր մոդուլ տեղադրելու համար:
4. Հաջորդը պետք է միացնի Microsoft Outlook Object-ը: Սեղմեք «Գործիքներ» > «Հղումներ»: Բացվող երկխոսության վանդակում գտեք և ստուգեք «Microsoft Outlook Object Library ”:
5. Հետևաբար, այս մոդուլում պատճենեք հետևյալ VBA կոդը:

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Ի վերջո, կարող եք փորձել:

• Սկզբում ընտրեք հատուկ բջիջները, ինչպես միշտ:
• Այնուհետև վերադարձեք նոր մակրո և սեղմեք F5 ստեղնը՝ այն գործարկելու համար:
• Միանգամից կցուցադրվի նոր Outlook նամակ, որում կարող եք տեսնել, որ ընտրված բջիջները տեղադրվել են էլփոստի մարմնի մեջ, ինչպես հետևյալ սքրինշոթը.

PST ֆայլը նույնքան խոցելի է, որքան Excel ֆայլը

Ինչպես գիտենք, Excel ֆայլը և Word փաստաթուղթը հակված են կոռուպցիայի: Փաստորեն, նույնը վերաբերում է PST ֆայլին, որը պարունակում է ձեր Outlook փոստարկղի բոլոր տարրերը: Այսպիսով, ձեր PST տվյալները ապահովելը դժվար գործ է: Նրանցից մեկըost արդյունավետ միջոց է ֆայլը պարբերաբար կրկնօրինակել: Բացի այդ, անհապաղ փրկություն ապահովելու համար ավելի լավ է պատրաստել փորձառու գործիք, ինչպիսին է DataNumen Outlook Repair, որն ի վիճակի է վերականգնել Outlook- ը տվյալներ ՝ առանց քրտինք կոտրելու:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերանորոգել mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com