Kako brzo ukloniti duplikate primatelja iz vaše Outlook e-pošte pomoću VBA

Ako dodate grupe kontakata u polje "Prima" trenutne e-pošte, među njima može biti nekoliko duplikata. Ovaj članak će vas naučiti kako koristiti VBA za brzo uklanjanje dvostrukih primatelja.

Prilikom sastavljanja e-pošte, ako kao primatelje ne dodate samo kontakte nego i grupe kontakata, ponekad može biti dupliciranih primatelja jer su grupe kontakata prema zadanim postavkama sažete. U ovom slučaju, ako želite pronaći duplikate, prvo morate proširiti grupe kontakata, a zatim ručno usporediti primatelje, što je detaljno predstavljeno u mom prethodnom članku – “Kako ukloniti duplikate primatelja iz vaše Outlook e-pošte”. Bez ikakve sumnje, vrlo je zamoran. Stoga mnogi korisnici čeznu za brzim načinom uklanjanja dvostrukih primatelja. U nastavku ćemo vas naučiti kako da ga dobijete pomoću programa Outlook VBA.

Brzo uklonite duplikate primatelja u svojoj Outlook e-pošti

1. Prvo pokrenite svoju Outlook aplikaciju.
2. Zatim prijeđite na karticu "Developer" i kliknite na gumb "Visual Basic" ili samo pritisnite tipke "Alt + F11".
3. Zatim u prozoru "Microsoft Visual Basic za aplikacije" možete otvoriti prazan modul.
4. Nakon toga kopirajte i zalijepite sljedeće VBA kodove u ovaj modul.

Sub RemoveDuplicateRecipients()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact groups in "To" field
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend
 
    'Remove the duplicate recipients
    For i = objRecipients.Count To 1 Step -1
        For n = (i - 1) To 1 Step -1
            If objRecipients(i).Address = objRecipients(n).Address Then
               objRecipients(i).Delete
               Exit For
            End If
        Next
    Next
End Sub

5. Nakon toga možete dodati novi VBA projekt u alatnu traku za brzi pristup prozora s porukama.
6. Kasnije ćete morati postaviti razinu sigurnosti Outlook makroa na nisku.
7. Konačno možete pokušati.

• Prvo samo sastavite e-poruku kao i obično.
• Zatim dodajte grupe kontakata i kontakte u polje "Prima".
• Zatim možete kliknuti novi makro gumb na alatnoj traci za brzi pristup.
• Odjednom će Outlook automatski proširiti grupe kontakata i zatim ukloniti dvostruke primatelje.

Zaštitite svoje vrijedne Outlook podatke

Budući da je Outlook sklon rušenju, vaši Outlook podaci osjetljivi su na oštećenje. Dakle, morate uložiti mnogo napora da zaštitite svoju Outlook datoteku. Prije svega, trebate redovito sigurnosno kopirati svoju PST datoteku. To će olakšati pokvareni PST popravak. Osim toga, bolje pripremite moćan alat za popravak pri ruci, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući mdf fix i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com