Kako brzo spojiti i izvesti više priloga Excel radne knjige u jednu radnu knjigu u programu Outlook

Kada primite e-poruku u privitku s više Excel radnih knjiga, ako želite provjeriti sadržaj svih radnih knjiga u jednoj radnoj knjizi, možete koristiti način u ovom članku. Izvest će više priloga Excel radne knjige u jednu radnu knjigu.

Da biste pregledali sve privitke Excel radne knjige e-pošte u jednoj Excel radnoj knjizi, prvo biste trebali kombinirati i izvesti te privitke u jednu radnu knjigu. Umjesto da to radite ručno, možete koristiti sljedeću metodu kako biste to postigli bez napora. Naučit će vas kako koristiti VBA kod za to. Što se tiče korištenja VBA, možete se obratiti objavi "Kako pokrenuti VBA kod u vašem Outlooku".

Spojite i izvezite više priloga Excel radne knjige u jednu radnu knjigu

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim pristupite Outlook VBA uređivaču.
3. Zatim, u novom prozoru „Microsoft Visual Basic for Applications“ trebate omogućiti „MS Excel Object Library“, o čemu možete pročitati članak – „Kako dodati referencu biblioteke objekata u VBA".
4. Nakon toga kopirajte sljedeći VBA kod u projekt ili modul.

Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Nakon toga možete zatvoriti prozor i dodati novu makronaredbu na alatnu traku za brzi pristup.
6. Kasnije, predstavite izvornu e-poštu na popisu e-pošte.
7. Zatim držite tipku “Ctrl” za odabir privitaka radne knjige programa Excel koje želite izvesti.
8. Zatim kliknite gumb makronaredbe na alatnoj traci za brzi pristup.
9. Kada se makronaredba završi, prikazat će se nova Excel radna knjiga. Sadržat će sadržaj prethodno odabranih Excel radnih knjiga.

Vratite se moćnijem vanjskom alatu za popravak

Prilikom susreta s oštećenjem Outlooka, većina korisnika će obično koristiti alat za popravak inboxa probati na prvom mjestu. Međutim, to neće biti od velike pomoći u slučaju ozbiljne štete. U tom trenutku nemate izbora nego uzeti pomoć vanjskog pouzdanog i iskusnog alata, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući mdf oporavak i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com