Kako brzo pretvoriti sve ugrađene slike u privitke u vašoj Outlook e-pošti

Ako želite brzo promijeniti sve slike ugrađene u tijelo poruke u privitke e-pošte, ne morate ih ručno ukloniti i ponovno priložiti. Možete jednostavno upotrijebiti dio VBA koda izložen u ovom članku.

Ponekad ćete možda htjeti grupno pretvoriti sve ugrađene slike u privitke. Na primjer, previše slika u tijelu poruke ometat će vas u čitanju teksta u tijelu. Stoga ih želite ukloniti iz tijela e-pošte i umjesto toga dodati kao privitke. Naravno, to možete učiniti ručno. Ali mora biti zgodnije ako bilo koji alati ili VBA kodovi mogu ovo dobiti odjednom. Ovdje ćemo vam otkriti takav VBA kod.

Brzo pretvorite sve ugrađene slike u privitke

1. Prvo pokrenite Outlook.
2. Zatim se možete prebaciti na karticu "Developer" i pritisnuti gumb "Visual Basic".
3. Zatim ćete ući u Outlook VBA prozor uređivača.
4. Nakon toga trebate kopirati sljedeći VBA kod u prazan modul.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Nakon toga trebate potvrditi da je vaš Outlook postavljen da dopušta makronaredbe.
6. Po izboru, ako vam je ovo često potrebno, bilo bi bolje da dodate novu makronaredbu na alatnu traku za brzi pristup za buduću praktičnu provjeru.
7. Na kraju možete pokušati. Odaberite ili otvorite e-poštu, a zatim pokrenite makronaredbu klikom na gumb za novu makronaredbu na alatnoj traci za brzi pristup.
8. Odmah će sve ugrađene slike biti promijenjene u privitke kao na sljedećoj snimci zaslona:

Trikovi za zaštitu vaših vrijednih Outlook podataka

Kao što svi znamo, Outlook PST datoteka jednako je ranjiva kao i uobičajene datoteke, poput Word dokumenata ili Excel proračunskih tablica. Stoga biste trebali nastaviti paziti na sve rizike oko svoje PST datoteke, poput virusa ili nepravilnog rukovanja. Stoga morate redovito izrađivati ​​sigurnosne kopije podataka za svoju PST datoteku. Također, ako si to možete priuštiti, mudro je zadržati robusnu Outlook popravak alat pri ruci, kao DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com