Kako automatski označiti sastanke za vikend kao privatne u programu Outlook

Za most korisnika, termini zakazani vikendom najčešće su privatni. Stoga žele da Outlook automatski označi i prikaže takve sastanke kao privatne. U ovom članku ćemo to ostvariti uz malo skriptiranja.

Kako bi lakše razlikovali poslovne od privatnih termina, Outlook korisnicima omogućuje označavanje sastanaka kao privatnih. Na ovaj način će vam biti vrlo praktično i jednostavno ispisivati ​​kalendar bez privatnih sastanaka. U ovoj situaciji možda želite da vaš Outlook automatski prepozna i označi određene sastanke kao privatne. Na primjer, općenito, sastanci vikendom su privatni, stoga želite dopustiti da ih Outlook automatski označi kao privatne. Nakon toga, vodit ćemo vas da to postignete.

Automatsko označavanje termina za vikend kao privatnih

1. Najprije pokrenite Outlook VBA uređivač prema "Kako pokrenuti VBA kod u vašem Outlooku".
2. Zatim u prozoru "Microsoft Visual Basic za aplikacije" stavite sljedeći kod u projekt "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. Nakon toga, reztart Outlook za aktiviranje makronaredbe.
4. Od sada, svaki put kada kreirate novi termin ili promijenite postojeći termin na vikend, Outlook će ga automatski označiti kao privatnog.

Riješite dosadne probleme s Outlookom

Moguće je da ste naišli na neke probleme dok ste radili s Outlookom, kao što je neočekivano zamrzavanje aplikacije, skočne poruke o pogrešci i tako dalje. Kada ih patite, bili biste zabrinuti. Molim te smiri se! Panika neće ništa pomoći, ali samo pogoršati situaciju. Kao prvo, možete provjeriti možete li pristupiti PST datoteci kao i obično. Ako je tako, morate popraviti PST datoteku, što se može postići putem alat za popravak inboxa ili moćniji vanjski alat, npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popravak mdf-a i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com