Kako grupno izvesti sve poruke e-pošte u razgovoru kao tekstualne datoteke putem programa Outlook VBA

Ponekad ćete možda poželjeti skupno snimiti sve poruke e-pošte u određenom razgovoru, a zatim ih grupno izvesti u lokalnu mapu kao tekstualne datoteke. Ovaj članak će vas naučiti kako to brzo dobiti.

Iz nekog razloga, možda ćete morati izvesti sve poruke e-pošte u određenom razgovoru na svoj lokalni pogon. Ako to radite ručno, odnosno pronalaženje i spremanje jednog po jednog, bit će to zamoran i naporan zadatak. Stoga je bolje da potražite drugu bržu metodu, poput sljedeće. Koristit će dio VBA koda da ga dobije bez puno znojenja.

Skupni izvoz svih poruka e-pošte u razgovoru kao tekstualnih datoteka

1. Na samom početku pokrenite svoju Outlook aplikaciju.
2. Zatim pritisnite tipke "Alt + F11" za pristup Outlook VBA uređivaču.
3. Nakon toga u novom prozoru trebate otvoriti modul koji nije u upotrebi ili izravno umetnuti novi modul.
4. Zatim trebate kopirati i zalijepiti sljedeće VBA kodove u ovaj modul.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Nakon toga možete dodati novi VBA projekt na alatnu traku za brzi pristup kao i obično.
6. Kasnije provjerite razinu sigurnosti Outlook makroa na nisku.
7. Na kraju, možete pokušati.

• Najprije odaberite e-poštu.
• Zatim kliknite novi makro gumb na alatnoj traci za brzi pristup.
• Kada dobijete poruku "Dovršeno", možete otvoriti unaprijed definiranu lokalnu mapu u kojoj ćete vidjeti e-poruke u "TXT" formatu.

Savjeti za vraćanje PST podataka nakon oštećenja

Često se u Outlooku možete susresti s raznim Outlookovim pogreškama, od kojih neke mogu biti izuzetno ozbiljne tako da izravno dovedu do oštećenja PST-a. U to vrijeme trebate poduzeti radnje popraviti PST da biste pronašli svoje vrijedne podatke. U ovom slučaju, možete se samo vratiti uglednom i dobro dokazanom alatu, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti se sql server i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com