Kako automatski postaviti Outlook online ili offline na temelju vašeg radnog vremena

Neki korisnici željeli bi postaviti Outlook da se automatski prebacuje između online i offline statusa na temelju njihovog radnog vremena. Stoga ćemo u ovom članku s vama podijeliti brzu metodu.

Zapravo, postavljanje Outlooka online ili offline vrlo je jednostavno. Da biste Outlook prebacili u izvanmrežni status, jednostavno se prebacite na karticu "Pošalji/primi" i pritisnite gumb "Rad izvan mreže". A da se vratite na mrežni status, jednostavno ponovno pritisnite ovaj gumb. Međutim, neki se korisnici nadaju da se Outlook može automatski prebaciti u izvanmrežni status kada je izvan radnog vremena i vratiti se na mrežu u radno vrijeme. Iako Outlook ne nudi takvu značajku, još uvijek možete upotrijebiti sljedeći VBA kod da biste je postigli.

Automatski postavite Outlook online ili offline na temelju vašeg radnog vremena

1. Na samom početku pokrenite Outlook aplikaciju.
2. Zatim, nakon što dobijete pristup svom Outlooku, trebali biste otvoriti mapu Zadaci.
3. Zatim biste trebali izraditi stavku zadatka koja se ponavlja svaki dan.

• Kliknite gumb "Novi zadatak" na vrpci.
• Zatim unesite "Izvan mreže" u redak Predmet zadatka.
• Zatim kliknite na gumb "Ponavljanje" pod karticom "Zadatak".
• U skočnom dijaloškom okviru odaberite uzorak ponavljanja "Dnevno", omogućite "Bez datuma završetka" i pritisnite "U redu".
• Zatim biste trebali omogućiti podsjetnik u "5:00".
• Na kraju pritisnite gumb "Spremi i zatvori".

4. Nakon toga, morate stvoriti još jedan dnevni ponavljajući zadatak pod nazivom "Online" i omogućiti podsjetnik u "8:00 ujutro", prikazan kao slika ispod:
5. Nakon toga, u glavnom prozoru programa Outlook pritisnite tipke "Alt + F11".
6. Zatim ćete dobiti pristup Outlook VBA uređivaču, u kojem trebate pronaći i otvoriti projekt “ThisOutlookSession”.
7. Kasnije kopirajte sljedeći VBA kod u ovaj projekt.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Na kraju možete ponovno pokrenuti Outlook da biste aktivirali ovaj makro.
9. Od sada će vaš Outlook biti online u radnom vremenu i automatski se prebaciti u offline status izvan radnog vremena.

Vaše zadnje utočište u slučaju pada Outlooka

Iako se Outlook može pohvaliti brojnim značajkama, Outlook još uvijek ne može izbjeći pogreške i štetu. Ali nemojte paničariti. Sve dok poduzmete odgovarajuće mjere opreza, još uvijek možete učinkovito zaštititi svoje Outlook podatke. Na primjer, trebali biste redovito sigurnosno kopirati svoje PST datoteke jer će vam sigurnosne kopije omogućiti povratak pokvareni PST podaci. Također, čuvanje moćnog alata za popravak, npr DataNumen Outlook Repair, također je stvar nužnosti.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popraviti mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com