Kako automatski postaviti različito vrijeme podsjetnika za Outlook sastanke u različitim kategorijama boja

Ako klasificirate Outlookove sastanke prema kategorijama boja i želite postaviti različito vrijeme podsjetnika za sastanke u različitim kategorijama boja, možete pogledati ovaj članak. Ovdje ćemo vas naučiti kako to realizirati s Outlook VBA.

Na primjer, dijelite sastanke u dvije grupe. Jedna je u kategoriji boja "Izvan lokacije" jer je lokacija sastanka previše udaljena, a druga je u kategoriji boja "Na licu mjesta" jer je lokacija upravo ovdje. Sada želite da Outlook može automatski postaviti vrijeme podsjetnika za sastanak "izvan lokacije" kao 1 sat prije početka, a za sastanak "na licu mjesta" kao 15 minuta prije početka. Uzimajući u obzir ovaj zahtjev, u nastavku ćemo podijeliti brzu metodu.

Automatski postavite različite podsjetnike za sastanke u različitim kategorijama boja

1. Za početak pokrenite Outlook aplikaciju.
2. Zatim pritisnite tipke "Alt + F11" za pristup prozoru uređivača VBA.
3. Zatim u sljedećem prozoru kopirajte i zalijepite VBA kod u nastavku u projekt “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Kasnije, trebate kliknuti na potprogram "Application_Startup" i pritisnuti tipku "F5" za pokretanje ovog makroa.
5. Od tada, svaki put kada se novi sastanak doda u zadani kalendar ili kada promijenite postojeći sastanak, Outlook će automatski provjeriti kategorije sastanka i automatski postaviti drugačije vrijeme podsjetnika.

Uklonite Outlook pogreške

S vremena na vrijeme mogu se pojaviti razni problemi s Outlookom. Stoga je izuzetno važno da korisnici nauče kako se nositi s problemima u Outlooku. Za početak, bolje je redovito izrađivati ​​sigurnosne kopije podataka Outlooka. Štoviše, ako je to pristupačno, preporučuje se imati snažnu sigurnosnu kopiju... Outlook popravak alat u blizini, npr DataNumen Outlook Repair. Može skenirati vašu PST datoteku kako bi otkrio probleme s Outlookom i zatim ih s lakoćom riješio.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql oporavak i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com