Kako automatski izvesti informacije o dolaznim porukama e-pošte u Excel datoteku s programom Outlook VBA

Mnogi se korisnici nadaju da Outlook može automatski izvesti primarne informacije dolazne e-pošte u Excel datoteku. Ovaj će članak razmotriti ovaj zahtjev i predstaviti brzu metodu putem Outlook VBA.

Ponekad, iz nekih razloga, kao što je statistika e-pošte, možda ćete često morati izvesti e-poštu u Excel datoteku. Općenito, za postojeće primljene e-poruke možete jednostavno upotrijebiti značajku "Uvoz i izvoz" da ih izvezete u Excel u jednom potezu. Međutim, možda čak želite da Outlook može automatski izvesti dolazne e-poruke u Excel čim stignu u vaš poštanski sandučić. Bez ikakve sumnje, takva izvorna značajka u Outlooku ne postoji. Stoga morate upotrijebiti druge pristupe, poput dodatka treće strane ili Outlook VBA. Ovdje ćemo vas naučiti kako to učiniti automatskim s Outlook VBA. Čitajte dalje da biste saznali korake i odgovarajuće kodove.

Automatski izvoz informacija o dolaznim porukama e-pošte u Excel datoteku

1. Prije svega, trebali biste izraditi Excel datoteku.

• Otvorite novu Excel datoteku.
• Zatim biste trebali upisati "Ne". u ćeliji A1, "Ime pošiljatelja" u ćeliji B1, "Adresa e-pošte pošiljatelja" u ćeliji C1 i "Predmet e-pošte" u ćeliji D1 i "Primljeno vrijeme" u ćeliji E1, kao na sljedećoj slici.
• Na kraju ga spremite u željeno ime i željenu mapu.

2. Nakon toga trebali biste pokrenuti Outlook.
3. Zatim pritisnite tipke "Alt + F11", što će vas dovesti do VBA uređivača.
4. Zatim u skočnom prozoru trebate dvaput kliknuti "ThisOutlookSession" na lijevoj strani.
5. Nakon toga, u prozoru projekta “ThisOutlookSession” trebate kopirati i zalijepiti sljedeće VBA kodove.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Kasnije biste trebali potpisati ovaj kod.
7. Naknadno, reztart Outlook za aktiviranje novog VBA projekta.
8. Naposljetku, od sada će se sve dolazne e-poruke automatski izvoziti u unaprijed postavljenu Excel datoteku čim dospiju u vašu mapu Inbox. Excel datoteka će izgledati kao sljedeća slika:

Spriječite bolno oštećenje PST podataka

Outlook je zaradio mnogo pohvala zbog svojih raznih značajki. Međutim, to ne znači da je siguran. I dalje se može kompromitirati u bilo kojem trenutku. Na primjer, ako često nepropisno zatvarate Outlook, vrlo je vjerojatno da će vaši PST podaci biti dovedeni u opasnost. U ovom slučaju, ako biste htjeli popraviti PST podataka, morate se obratiti iskusnom alatu, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com