Kako automatski onemogućiti hiperveze u dolaznoj Outlook e-pošti od nepoznatih pošiljatelja

Da biste blokirali zlonamjerne veze, bolje konfigurirajte svoj Outlook da automatski onemogući hiperveze u dolaznim porukama e-pošte od nepoznatih pošiljatelja. Ovaj članak će otkriti dio VBA koda koji vam može pomoći da ga dobijete kao čep.

Mnogi su se korisnici žalili da su im virusi iz e-pošte napali Outlook datoteku. Češće nego ne, to je zato što spremno vjeruju tim e-porukama od nepoznatih pošiljatelja. Stoga preuzimaju ili klikaju na hiperveze u mailovima. Sada, nakon toga, podijelit ćemo metodu. Može dopustiti Outlooku da automatski onemogući hiperveze dolazne e-pošte od nepoznatih pošiljatelja. Ako imate takve potrebe, pročitajte dalje da biste saznali više pojedinosti.

Automatski onemogući hiperveze u dolaznim porukama e-pošte od nepoznatih pošiljatelja

1. Za početak, u Outlooku idite na VBA editor pomoću "Alt + F11".
2. Zatim, na novom ekranu, dodajte objekt "MS VBScript Regular Expressions" kao što je navedeno u objavi "Kako dodati referencu biblioteke objekata u VBA".
3. Zatim kopirajte i zalijepite sljedeći kod u projekt “ThisOutlookSession”.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Nakon toga, aktivirajte ovaj makro ponovnim pokretanjem Outlooka ili pritiskom na tipku "F5" u potprogramu "Application_Startup".
5. Od tada, svaki put kada e-pošta koja dolazi od pošiljatelja, a koja nije pohranjena u zadanoj mapi kontakata, stigne u Inbox, Outlook će automatski onemogućiti hiperveze u njoj.

Nekoliko nužnih stvari u Outlook zaštiti

Budući da je Outlook osjetljiv na oštećenja, prilično je teško zaštititi Outlook datoteku. Ovdje ćemo navesti nekoliko stvari koje morate imati tijekom Outlook zaštite podataka. Prije svega, morate redovito sigurnosno kopirati svoje Outlook podatke. Štoviše, bitno je da se čuvate svih potencijalnih rizika, poput zlonamjernih privitaka ili hiperveza. Na kraju, ali ne manje važno, trebali biste unaprijed pripremiti moćan alat za popravak programa Outlook, npr DataNumen Outlook Repair. Sigurno će vam dobro doći kada budete trebali popraviti PST datoteka, ali alat za popravak pristigle pošte dokazuje neuspjeh.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com