3 brza načina za brisanje praznih redaka i stupaca u vašoj Word tablici

U ovom postu objasnit ćemo vam 3 brza načina za brisanje praznih redaka i stupaca u vašoj Word tablici.

Tablice su bitne za dokument, posebno za držanje različitih vrsta podataka. Ponekad duga tablica može premašiti stranicu i proširiti se na nekoliko stranica. Dakle, kada tablica postane dugačka i komplicirana, postoje mjere koje možete učiniti da je pojednostavite. Na primjer, možete izbrisati nepotrebne prazne retke i stupce.

Slijede 3 metode koje možete koristiti.

Metoda 1: Ručno brisanje praznih redaka i stupaca

1. Prvo odaberite prazan redak ili stupac.
2. Zatim kliknite desnom tipkom da biste dobili kontekstualni izbornik. Na izborniku odaberite "Izbriši retke" ili "Izbriši stupce" u skladu s tim.

Nažalost, ne možete odabrati više redaka ili stupaca koji nisu uzastopni i izbrisati ih zajedno na ovaj način. Za ovu potražnju možete pogledati naš prethodni članak: 5 brzih metoda za skupno brisanje više redaka ili stupaca u vašoj Word tablici

Metoda 2: Skupno brisanje svih praznih redaka i stupaca u tablici

Metoda 1 ima svoje ograničenje. Stoga ćemo vam ponuditi način skupnog uklanjanja redaka i stupaca u tablici putem VBA kodova.

1. Za početak, postavite kursor unutar ciljne tablice.
2. Drugo, pokrenite VBA editor pritiskom na “Alt+ F11”.
3. U uređivaču najprije kliknite projekt "Normalno".
4. Zatim kliknite karticu "Umetni" na traci izbornika.
5. Na padajućem izborniku odaberite "Modul".
6. Dvaput kliknite na modul da ga otvorite i tamo zalijepite sljedeće kodove:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Na kraju kliknite gumb "Pokreni" na traci izbornika ili pritisnite "F5".

U sekundi ćete ukloniti sve prazne retke i stupce u toj tablici.

Metoda 3: Skupno brisanje svih praznih redaka i stupaca u svim tablicama u dokumentu

1. Najprije ponovite korake iz metode 2 da biste instalirali i pokrenuli makro.
2. Samo ovaj put zamijenite tu makronaredbu sljedećim:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Oporavak pokvarenog dokumenta

Danas postoji više od jednog načina za vraćanje izgubljenih podataka. Na primjer, pribjegavanje sigurnosnim kopijama uvijek ostaje vaš glavni prioritet. Ako to ne zadovoljava vašu potrebu za vraćanjem najnovijih informacija, možete pokušati... popravak dok alat.

Uvod za autora:

Vera Chen stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući xlsx popravak i pdf popraviti softverske proizvode. Za više informacija posjetite www.datanumen.com