2 načina ispisa popisa Outlook zadataka s različitim kategorijama na različitim stranicama

Ako ste svojim Outlook zadacima dodijelili različite kategorije boja i sada želite ispisati popise zadataka s različitim kategorijama na različitim stranicama, možete pogledati ovaj članak. Ovdje ćemo s vama podijeliti 2 metode kako ga dobiti.

Kako biste klasificirali svoje zadatke i dobro upravljali njima, možda ste na svoje zadatke primijenili kategorije boja. Sada, ako želite ispisati popise svojih zadataka s različitim kategorijama na različitim stranicama, čitajte dalje. U nastavku ćemo vam predstaviti 2 načina da ga dobijete.

Metoda 1: Ručni ispis popisa zadataka jedan po jedan

1. Prvo, u programu Outlook pristupite oknu "Zadaci".
2. Zatim otvorite mapu zadataka.
3. Zatim pritisnite “Ctrl + E” da aktivirate vrpcu “Traži”.
4. Nakon toga, na kartici "Traži", kliknite gumb "Kategoriziraj".
5. S padajućeg popisa odaberite kategoriju boja.
6. Tada će na popisu ostati samo zadaci s odabranom kategorijom.
7. Sada idite na “Datoteka” > “Ispis” da biste ispisali ovaj popis zadataka.
8. Nakon toga, na isti način, ručno ispišite popise zadataka s ostalim kategorijama boja jednu po jednu.

Metoda 2: Skupni ispis popisa zadataka pomoću VBA

1. Na samom početku pokrenite VBA uređivač prema "Kako pokrenuti VBA kod u vašem Outlooku".
2. Zatim dodajte referencu na “MS Excel Object Library" prema "Kako dodati biblioteku objekatarary Referenca u VBA".
3. Zatim kopirajte sljedeći VBA kod u modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Nakon toga pritisnite tipku "F5" da biste odmah pokrenuli ovu makronaredbu.
5. Kada makronaredba završi, popisi zadataka s različitim kategorijama bit će ispisani na različitim stranicama, kao što je prikazano na sljedećoj snimci zaslona.

Vratite vrijedne podatke iz ugrožene PST datoteke

Ako ste podložni nedostupnoj PST datoteci, vaš sljedeći korak je nedvojbeno PST popravak. U tom slučaju prvo možete isprobati alat za popravak pristigle pošte. Pod uvjetom da ne uspije, možete pokušati s drugim vanjskim alatom, kao što je DataNumen Outlook Repair. Može brzo oporaviti PST podatke.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com