2 metode za brzo prebrojavanje e-pošte prema pošiljatelju u vašem Outlooku

Ako želite prebrojati e-poruke po pošiljatelju, pogledajte ovaj članak. Ovdje ćemo vam predstaviti 2 brza pristupa.

Kako biste saznali koji je najaktivniji pošiljatelj, možda biste trebali brojati e-poruke po pošiljatelju. Iako Outlook ne nudi izravnu značajku za to, i dalje možete potražiti neka rješenja, kao što je sljedeća Metoda 1. Ako mislite da je Metoda 1 previše zamorna, možete se odlučiti za Metodu 2. Mnogo je učinkovitija jer koristi VBA za brzo brojanje e-poruka po pošiljatelju i izvoz brojača u Excel. Sada detaljno pročitajte dva načina. Ovdje ćemo uzeti e-poruke u Inboxu kao primjer.

Metoda 1: Dohvaćanje brojeva nakon grupiranja stavki prema polju "Od".

1. Za početak pokrenite Outlook aplikaciju.
2. Zatim otvorite mapu ulazne pošte.
3. Zatim prijeđite na karticu "Prikaz".
4. Nakon toga odaberite “Od” u grupi “Aranžman”.
5. Odjednom su sve stavke ulazne pošte razdvojene u različite grupe prema različitim pošiljateljima.
6. Sada, za brojanje stavki od određenog pošiljatelja, možete odabrati sve stavke u povezanoj grupi i pritisnuti tipku "Enter". U skočnom prozoru upozorenja možete vidjeti broj.

To znači da je prilično jednostavno, ali brojevi stavki zapravo uključuju druge vrste stavki, kao što su pozivnice za sastanke, zahtjevi za zadacima i potvrde, a ne samo brojevi e-pošte. Stoga, ako želite brojati samo e-poštu, umjesto toga možete koristiti sljedeći način.

Metoda 2: Prebrojavanje poruka e-pošte po pošiljatelju uz Outlook VBA

1. Za početak, pritisnite tipke "Alt + F11" u Outlooku.
2. Zatim omogućite „MS Excel Object Library“ prema uputama „Kako dodati referencu biblioteke objekata u VBA".
3. Zatim kopirajte donji kod u neiskorišteni modul.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Nakon toga pritisnite tipku "F5".
4. Kada makronaredba završi, prikazat će se nova Excel datoteka.
5. Kao što vidite, sadrži broj e-poruka u pristigloj pošti od različitih pošiljatelja.

Riješite se frustrirajućih problema s Outlookom

Možda ste ikada bili izloženi mnogim problemima u svom Outlooku. Kako biste ih učinkovito riješili, možda čeznete za svestranim i moćnim načinom. Ipak, zapravo, ne postoji takva metoda. Ono što možete učiniti je čuvati se vlastitih operacija u Outlooku i redovito raditi sigurnosne kopije. Naravno, ako je moguće, predlažemo da pri ruci držite iskusan alat za popravak, npr DataNumen Outlook Repair. Može riješiti razne PST probleme i popraviti pokvareni PST turpija poput povjetarca.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti se Sql Server i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com