Kuinka yhdistää ja viedä useita Excel-työkirjan liitteitä nopeasti yhteen työkirjaan Outlookissa

Kun saat sähköpostin, johon on liitetty useita Excel-työkirjoja, voit käyttää kaikkien työkirjojen sisältöä yhdessä työkirjassa, voit käyttää tapaa tässä artikkelissa. Se vie useita Excel-työkirjan liitteitä yhteen työkirjaan.

Jos haluat tarkastella sähköpostin kaikkia Excel-työkirjan liitteitä yhdessä Excel-työkirjassa, sinun on ensin yhdistettävä ja vietävä nämä liitteet yhteen työkirjaan. Sen sijaan, että tekisit sen manuaalisesti, voit käyttää seuraavaa menetelmää sen saavuttamiseksi vaivattomasti. Se opettaa käyttämään VBA-koodia sen saavuttamiseksi. VBA: n käytöstä voit katsoa sivuaost "Kuinka suorittaa VBA-koodi Outlookissa".

Yhdistä ja vie useita Excel-työkirjan liitteitä yhdeksi työkirjaksi

1. Sillä kutentart, käynnistä Outlook-sovellus.
2. Avaa sitten Outlook VBA -editori.
3. Seuraavaksi sinun on otettava uudessa Microsoft Visual Basic for Applications -ikkunassa käyttöön MS Excel Object Library ", josta voit viitata artikkeliin -"Objektin lisääminen Library Viite VBA: ssa".
4. Kopioi sitten seuraava VBA-koodi projektiin tai moduuliin.

Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Tämän jälkeen voit sulkea ikkunan ja lisätä uuden makron Pikatyökaluriville.
6. Myöhemmin sävele lähdesähköposti postituslistalla.
7. Pidä sitten Ctrl-näppäintä painettuna valitaksesi Excel-työkirjan liitteet, jotka haluat viedä.
8. Napsauta seuraavaksi makron painiketta Pikakäynnistystyökalurivillä.
9. Kun makro on valmis, uusi Excel-työkirja tulee näkyviin. Se sisältää aiemmin valittujen Excel-työkirjojen sisällön.

Palaa takaisin Mightier-ulkoisen korjaustyökalun päälle

Kun tapaat Outlookin korruptiota, most käyttäjät pyrkivät käyttämään Saapuneet-kansion korjaustyökalu kokeilla ensin. Siitä ei kuitenkaan ole paljon apua vakavien vahinkojen sattuessa. Siinä vaiheessa sinulla ei ole muuta vaihtoehtoa kuin ottaa apua ulkoisesta luotettavasta ja kokeneesta työkalusta, kuten DataNumen Outlook Repair.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien mdf-palautus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com