Kuinka kiinnittää nopeasti tietyt diot a PowerPoint Esitys Outlook-sähköpostiisi

Jos haluat poimia tietyt diat a PowerPoint esityksen erilliseen uuteen esitykseen ja liitä se Outlook-sähköpostiin, voit hyödyntää tässä artikkelissa kuvattua tapaa.

Kokonaisen liittämisen sijaan PowerPoint esitys sähköpostiin, jos haluat liittää esityksen tietyt diat, yleensä sinun on ensin kopioitava tietyt diat uuteen esitykseen. Se on liian hankalaa. Siksi tässä näytämme sinulle menetelmän, joka voi toteuttaa sen yhdellä kertaa.

Kiinnitä a.:n tietyt diat PowerPoint Esittely sähköpostiin

1. Avaa ensin tietty PowerPoint esitys.
2. Sitten PowerPoint sovellusikkunassa, paina "Alt + F11" -näppäimiä päästäksesi VBA-editoriin.
3. Luo seuraavaksi uudessa ikkunassa uusi moduuli napsauttamalla "Lisää" > "Moduuli".
4. Kopioi ja liitä seuraava VBA-koodi tähän moduuliin.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Tämän jälkeen voit sulkea nykyisen ikkunan.
6. Siirry myöhemmin kohtaan "Tiedosto" > "Asetukset" > "Pikakäyttötyökalupalkki" lisätäksesi uuden makron pikatyökalupalkkiin.
7. Lopuksi voit kokeilla tätä makroa.

• Aloita valitsemalla ne diat, jotka haluat poimia.
• Napsauta sitten pikakäynnistystyökalurivin makropainiketta.
• Heti näkyviin tulee Outlook-sähköposti, jossa on a PowerPoint esitys, joka on poimittu lähdeesityksestä.

Käytä tehokasta palautustyökalua

Kuten me kaikki tiedämme, Outlook on varustettu sisäänrakennetulla korjausapuohjelmalla - scanpst. Silti se voi yksinkertaisesti selviytyä pienistä virheistä Outlookissa. Jos kohtaamasi vahinko on vakava, sillä ei ole vaikutuksia. Siinä vaiheessa sinulla ei ole muuta vaihtoehtoa kuin turvautua toiseen tehokkaaseen ja luotettavaan korjaustyökaluun, kuten DataNumen Outlook Repair. Sen avulla pystyt pelastamaan vioittuneen Outlook-tiedoston.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien vioittunut mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com