Äänestystilastojen vieminen nopeasti Outlook-sähköpostista Excel-laskentataulukkoon

Jos olet lähettänyt sähköpostin, jossa on äänestyspainikkeita, ja vastaanottajien lähetettyä vastauksensa, voit halutessasi laskea äänestystilastot ja viedä ne Excel-laskentataulukkoon. Tässä artikkelissa opetamme sinulle, miten se onnistuu nopeasti.

Outlook on niin tehokas, että se tarjoaa jopa "äänestys"-ominaisuuden. Edellinen artikkelini "MS Outlookin taitava käyttö äänestykseen” on opettanut, kuinka sitä käytetään tehokkaasti. Lisäksi useimmiten äänestämisen jälkeen voit viedä äänestystilastot Excel-laskentataulukkoon jostain syystä, kuten jos haluat tulostaa tilastot. Outlook ei kuitenkaan tue tätä oletusarvoisesti. Siksi seuraavassa opetamme sinulle, kuinka tämä toteutetaan kuin korkki.

Vie äänestystilastot sähköpostissa Excel-laskentataulukkoon

1. Käynnistä Outlook-sovellus heti alusta.
2. Sitten sinun tulee painaa "Alt + F11" -näppäinpainikkeita Outlookin pääikkunassa.
3. Seuraavaksi ”Microsoft Visual Basic for Applications” -ikkunassa sinun tulee ottaa käyttöön ”Microsoft Excel Object Library”. Valitse ”Työkalut” > ”Viite”. Valitse sitten ponnahdusikkunassa ”Microsoft Excel Object Library” -valintaruutu ja paina lopuksi ”OK”.
4. Tämän jälkeen voit lisätä uuden moduulin tai avata käyttämättömän.
5. Kopioi ja liitä seuraavat VBA-koodit sitten tähän moduuliin.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Tämän jälkeen sinun on parempi lisätä uusi makro Quick Access Toolbariin, jotta käyttö olisi helppoa.
6. Lopulta voit kokeilla.

• Valitse ensin lähdesähköposti, joka sisältää äänestyspainikkeita.
• Napsauta sitten pikakäynnistystyökalurivin makropainiketta.
• Kun tämä makro on suoritettu, voit selata ennalta määritettyyn paikalliseen kansioon, jossa näet uuden Excel-työkirjan.
• Avaa tämä Excel-työkirja. Nyt näet äänestystilastot alla olevan kuvan mukaisesti:

Kukaan ei voi estää Outlookin virheitä perusteellisesti

Vaikka Outlookissa on useita ominaisuuksia, meillä ei ole sellaista ominaisuutta, joka auttaisi meitä välttämään Outlook-virheet. Kaikenlaiset tekijät voivat aiheuttaa Outlook-virheitä. Jos esimerkiksi poistut usein Outlookista väärin, kärsit todennäköisesti siitä PST-korruptio. Tällaisessa tilanteessa sinulla ei ole muuta vaihtoehtoa kuin käyttää tehokkaita työkaluja PST-tiedoston pelastamiseen, kuten DataNumen Outlook Repair. Se on ansainnut paljon kiitosta korkean palautumisasteen ansiosta.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korruptoitunut mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com