Kuinka viedä useita Outlook-sähköpostiviestejä yhdeksi Word-asiakirjaksi VBA:n kautta

Jos haluat viedä useita Outlook-sähköpostiviestejä erässä yhdeksi Word-asiakirjaksi, voit käyttää tässä artikkelissa näkyvää VBA-koodia. Se voi auttaa sinua suorittamaan tämän tehtävän muutamassa sekunnissa.

Olen koskaan esitellyt, kuinka Outlook-sähköposti muunnetaan Word-asiakirjaksi edellisessä artikkelissani - "2 tehokasta tapaa muuntaa Outlook-sähköposti Word-asiakirjaksi”. Kuitenkin molemmat kyseisessä sivulla mainitut 2 tarkoittaaost on avuton, jos haluat viedä useita sähköpostiviestejä yhdeksi Word-asiakirjaksi. Siksi tässä opetamme sinulle toisen tavan. Lue nyt saadaksesi sen yksityiskohtaisesti.

Erävienti useita Outlook-sähköpostiviestejä yhdeksi Word-asiakirjaksi

1. Kohteeseen starKäynnistä Outlook-ohjelma.
2. Sitten, kun olet siirtynyt Outlookin pääikkunaan, sinun on painettava "Alt + F11" -näppäinpainikkeita.
3. Seuraavaksi pääset Outlook VBA -editoriin, jossa sinun pitäisi avata tyhjä moduuli.
4. Kopioi sen jälkeen alla oleva VBA-koodi avautuvaan moduuliikkunaan.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Sen jälkeen sinun on parempi lisätä tämä uusi VBA-projekti Quick Access -työkalupalkkiin tai -nauhaan.
6. Viime kädessä voit kokeilla.

• Valitse ensin useita Outlook-sähköpostiviestejä.
• Etsi sitten juuri lisätty makropainike ja napsauta sitä.
• Kun sinua kehotetaan "Complete", voit selata ennalta määritettyyn paikalliseen kansioon löytääksesi uuden Word-asiakirjan.
• Avaa tämä asiakirja, josta näet, että kaikki valitut sähköpostit on viety.

Pidä mahtava palautustyökalu lähellä

Huolimatta lukuisista toiminnoista, Outlook ei silti voi olla immuuni virheiltä. Jos olet tottunut jättämään virheet rauhaan, kun niitä kasaantuu, Outlook kaatuu varmasti. Siinä vaiheessa on välttämätöntä palata mahtavaan ja tehokkaaseen palautustyökaluun, kuten DataNumen Outlook Repair. Se on hyvin perehtynyt PST-korjaus. Niin kauan kuin se on käytössä, sinun ei tarvitse enää olla huolissaan Outlook-tietojen katoamisesta.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien vioittunut mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com