Kuinka viedä nopeasti Outlook-tapaamisiin käytetty aika kussakin väriluokassa

Jos haluat luoda raportin tapaamisiin käyttämästäsi ajasta kussakin värikategoriassa, voit käyttää tässä artikkelissa esiteltyä menetelmää. Se voi auttaa sinua saavuttamaan tämän nopeasti ilman manuaalista laskemista.

Monet käyttäjät ovat tottuneet kirjaamaan suurimman osan toiminnoistaan ​​Outlook-kalenteriin. Lisäksi, jotta toimintoja olisi helpompi hallita ja erottaa, he luokittelevat ne luokkiin. Tässä tapauksessa jotkut käyttäjät haluavat luoda raportin, joka näyttää kunkin väriluokan kalenterimerkintöihin käytetyn kokonaisajan. Niiden laskeminen ja syöttäminen manuaalisesti on epäilemättä hankalaa. Siksi jaamme tässä tavan, jolla tämä tehtävä voidaan suorittaa yhdellä napsautuksella.

Vie tapaamisiin käytetty kokonaisaika kussakin väriluokassa

1. Käynnistä ensin Outlook-sovellus.
2. Sitten Outlook-ikkunaan saapumisen jälkeen voit napauttaa "Alt + F11" -näppäinpainikkeita.
3. Myöhemmin pääset Microsoft Visual Basic for Applications -ikkunaan.
4. Seuraavaksi sinun on otettava käyttöön ”Microsoft Excel Object Library”. Voit tehdä sen napsauttamalla ”Työkalut” > ”Viite”.
5. Sitten sinun pitäisi löytää ja avata moduuli, joka ei ole käytössä.
6. Tämän jälkeen sinun on kopioitava seuraava VBA-koodi tähän moduuliin.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Lopuksi voit laukaista tämän makron napsauttamalla työkalupalkin "Suorita"-kuvaketta tai painamalla "F5"-näppäintä.
8. Sitten sinua pyydetään valitsemaan tietty kalenteri.
9. Kun olet valinnut ja painanut "OK", makro jatkuu. Kun se on valmis, taustalla näkyy uusi Excel-tiedosto.
10. Voit käyttää sitä. Se näyttää seuraavalta kuvakaappaukselta:

Pidä silmällä Outlookin ympärillä olevia mahdollisia uhkia

Outlook-käyttäjien tulee varoa kaikkia mahdollisia riskejä, mukaan lukien tuntemattomat sähköpostiliitteet, upotetut linkit ja inhimilliset virheet. Muuten Outlook voi vioittua milloin tahansa. Myös säännöllisten Outlook-tietojen varmuuskopiointi ja erikoistuneen korjaustyökalun säilyttäminen ovat välttämättömiä asioita. DataNumen Outlook Repair on yksi suositelluimmista korjaustyökaluista. Se voi korjata Outlook ongelmia hetkessä.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien vaurioitunut mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com