Erilaisten oletusmuistutusaikojen asettaminen erityyppisille merkityille kohteille Outlookissasi

Oletusarvoisesti Outlook käyttää automaattisesti tehtävien oletusmuistutusaikaa kaikenlaisille merkityille kohteille. Jos kuitenkin haluat käyttää eri muistutusaikoja merkittyjen kohteiden kohdalla tuotetyypin perusteella, voit viitata tässä artikkelissa esiteltyyn menetelmään.

Outlookin avulla voit asettaa oletusmuistutusajan kaikille merkityille kohteille kohdetyypistä riippumatta. Voit siirtyä "Tiedosto"-valikkoon ja napsauttaa "Asetukset". Sitten "Outlook-asetukset" -ikkunassa voit nähdä "Tehtävät"-välilehden "Oletusmuistutusaika" -vaihtoehdon, kuten seuraavassa kuvakaappauksessa näkyy.

Useimmat käyttäjät toivovat kuitenkin käyttävänsä eri muistutusaikoja erityyppisille merkityille viesteille, kuten ”9:00” merkityille sähköposteille ja ”17:30” merkityille yhteystiedoille. Seuraavaksi keskitymme tähän esimerkkiin esitelläksemme menetelmän.

Aseta erilainen oletusmuistutusaika erityyppisille merkittyille kohteille

1. Aloita käynnistämällä Outlook-sovellus.
2. Käytä sitten Outlook VBA -editoria viittaamallaKuinka suorittaa VBA-koodi Outlookissa".
3. Kopioi seuraavassa "Microsoft Visual Basic for Applications" -ikkunassa seuraava koodi "ThisOutlookSession" -projektiin.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Käynnistä sen jälkeen Outlook uudelleen aktivoidaksesi tämän makron.
5. Tästä lähtien aina, kun ilmoitat sähköpostista, muistutusajaksi asetetaan "10:00" liputuspäivänä.
6. Ja kun merkitset yhteystiedon, muistutusajaksi asetetaan "17:30" lipun eräpäivänä.

Käsittele Outlook-ongelmia joustavasti

Outlookissa voi ilmetä kaikenlaisia ​​ongelmia. Siksi sinun on opittava etukäteen joitakin toimenpiteitä niiden käsittelemiseksi. Jos esimerkiksi Outlook käynnistyy usein uudelleen, sinun on korjattava Office tai poistettava käytöstä kolmannen osapuolen lisäosat jne. Tai jos Outlook PST -tiedostosi vaarantuu, voit ensin kokeilla Saapuneet-kansion korjaustyökalu. Kun se epäonnistuu, voit jatkaa tehokkaan ulkoisen työkalun käyttöä, kuten DataNumen Outlook Repair.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien mdf-palautus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com