Outlookin automaattisen online- tai offline-asetusten määrittäminen työaikasi perusteella

Jotkut käyttäjät haluaisivat saada Outlookin vaihtamaan automaattisesti online- ja offline-tilan välillä työaikansa perusteella. Joten tässä artikkelissa jaamme kanssasi nopean menetelmän.

Itse asiassa Outlookin asettaminen online- tai offline-tilaan on erittäin helppoa. Voit muuttaa Outlookin offline-tilaan siirtymällä "Lähetä/vastaanota" -välilehdelle ja painamalla "Work Offline" -painiketta. Ja palataksesi online-tilaan painamalla tätä painiketta uudelleen. Jotkut käyttäjät kuitenkin toivovat, että Outlook voi siirtyä automaattisesti offline-tilaan, kun se on poissa työajasta, ja palata online-tilaan työaikana. Vaikka Outlook ei tarjoa tällaista ominaisuutta, voit silti käyttää seuraavaa VBA-koodia sen saavuttamiseen.

Aseta Outlook automaattisesti online- tai offline-tilaan työaikasi perusteella

1. Käynnistä Outlook-sovelluksesi aivan aluksi.
2. Sitten, kun olet saanut pääsyn Outlookiin, sinun pitäisi avata Tehtävät-kansio.
3. Seuraavaksi sinun tulee luoda päivittäin toistuva tehtäväkohde.

• Napsauta "Uusi tehtävä" -painiketta nauhassa.
• Kirjoita sitten tehtävän aiheriville "Offline".
• Napsauta seuraavaksi "Toistuvuus" -painiketta "Tehtävä" -välilehden alla.
• Valitse ponnahdusikkunassa "Päivittäinen" toistumiskuvio, ota käyttöön "Ei lopetuspäivää" ja paina "OK".
• Seuraavaksi sinun tulee ottaa muistutus käyttöön klo 5.
• Paina lopuksi "Tallenna ja sulje" -painiketta.

4. Tämän jälkeen sinun on luotava toinen päivittäin toistuva tehtävä nimeltä "Online" ja otettava käyttöön muistutus kello 8, joka näkyy alla olevan kuvan mukaisesti:
5. Paina sen jälkeen Outlookin pääikkunassa "Alt + F11" -näppäinpainikkeita.
6. Seuraavaksi pääset Outlook VBA -editoriin, jossa sinun on löydettävä ja avattava "ThisOutlookSession" -projekti.
7. Kopioi myöhemmin seuraava VBA-koodi tähän projektiin.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Lopulta voit aktivoida tämän makron käynnistämällä Outlookin uudelleen.
9. Tästä eteenpäin Outlook on online-tilassa työaikana ja siirtyy automaattisesti offline-tilaan työajan ulkopuolella.

Viimeinen keinosi Outlookin kaatumisen varalta

Vaikka Outlookissa on useita ominaisuuksia, Outlook ei silti voi pysyä poissa virheistä ja vaurioista. Mutta älä panikoi. Niin kauan kuin teet riittäviä varotoimia, voit silti suojata Outlook-tietosi tehokkaasti. Sinun tulisi esimerkiksi varmuuskopioida PST-tiedostosi säännöllisesti, koska varmuuskopioiden avulla voit palauttaa ne korruptoitunut PST tiedot. Myös tehokkaan korjaustyökalun säilyttäminen, kuten DataNumen Outlook Repair, on myös välttämättömyys.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korjaa mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com