Cómo descomprimir .RAR Archivos adjuntos directamente en Outlook a través de VBA

En general, para descomprimir el “.rarSi necesitas adjuntar archivos a un correo electrónico, primero debes guardarlo y luego usar una herramienta específica para extraer los archivos internos. Este artículo te mostrará cómo descomprimir archivos RAR directamente en Outlook.

Outlook no permite previsualizar el “.RAR” archivos adjuntos. Además, no puede descomprimir el “.RAR” archivos adjuntos directamente en Outlook. Por lo tanto, si desea ver un archivo adjunto de este tipo, primero debe guardarlo en la unidad local y luego extraer los archivos internos mediante una utilidad especial, como WinRAR. Centrándonos en este problema, aquí le ofreceremos una forma que le permitirá descomprimir “.RAR”Archivos adjuntos solo en Outlook. Ahora siga leyendo para obtener los pasos detallados y los códigos VBA.

Descomprimir .RAR Archivos adjuntos directamente en Outlook

1. En primer lugar, dado que este método depende de una herramienta específica (WinRAR), primero debe instalarla en su PC y asegurarse de dónde está montada.
2. Luego, podría abrir su aplicación de Outlook como de costumbre.
3. A continuación, presione los botones de tecla "Alt + F11" en la ventana principal de Outlook.
4. Posteriormente, en el editor de Outlook VBA, abra un módulo vacío.
5. Y luego copie el siguiente código VBA en este módulo.

Public objFileSystem As Object
Public strTempFolder As String
Public strTargetFolderPath As String
Public objAttachment As Outlook.Attachment

Sub UnRARAttachment()
    Dim objMail As Outlook.MailItem
    Dim objShell As Object
    Dim strTempFolder As String
    Dim strRARFile As String
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path
    strTargetFolderPath = strTempFolder & "\Temp " & Format(Now, "YYYY-MM-DD-hh-mm-ss")
    MkDir (strTargetFolderPath)
 
    Set objShell = CreateObject("Wscript.Shell")
 
    If objMail.attachments.Count > 0 Then
       For Each objAttachment In objMail.attachments
           If LCase(Right(objAttachment.FileName, 4)) = ".rar" Then
 
              strRARFile = strTempFolder & "\" & objAttachment.FileName
              objAttachment.SaveAsFile (strRARFile)
 
              'Change "C:\Program Files\WinRAR\WinRAR.exe" to the location where your WinRAR is installed
              objShell.Run Chr(34) & "C:\Program Files\WinRAR\WinRAR.exe" & Chr(34) & " e " & Chr(34) & strRARFile & Chr(34) & " " & Chr(34) & strTargetFolderPath & Chr(34)
           End If
       Next
    End If
 
End Sub

Sub AttachExtractedFiles()
    Dim strFolderPath As String
    Dim strFile As String
 
    'Attach the extracted files to the current email
    strFolderPath = strTargetFolderPath & "\"
    strFile = Dir(strFolderPath)
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
 
    While Len(strFile) > 0
          objMail.attachments.Add strFolderPath & strFile
          strFile = Dir
    Wend
 
    'Delete the .RAR attachments
    For Each objAttachment In objMail.attachments
        If LCase(Right(objAttachment.FileName, 4)) = ".rar" Then
           objAttachment.Delete
        End If
    Next
End Sub

6. Después de eso, debe asegurarse de que la macro esté permitida en su Outlook.
7. Finalmente puedes intentarlo.

• En primer lugar, abre un correo electrónico que contiene .RAR archivos adjuntos.
• Luego, regrese al nuevo botón de macro.
• Haz clic en la subrutina “UnRARAttachments” y pulsa F5.
• Y luego haga clic en la siguiente subrutina "AttachExtractedFiles" y presione la tecla F5.
• Después de eso, puede volver a la ventana de correo. Verá que .RAR los archivos adjuntos se han descomprimido. Se han adjuntado todos los archivos extraídos.

abrir la cremallera .Zip Archivos adjuntos en Outlook

Como descomprimir el .RAR adjuntos, Outlook no tiene funciones nativas para descomprimir el “.zip” archivos adjuntos. Por lo tanto, si no puede descomprimir directamente el “.Zip”Adjuntos directamente en Outlook de forma predeterminada. Afortunadamente, aún puede utilizar Outlook VBA para lograr esta función. Para obtener más detalles, puede consultar mi artículo anterior: "Cómo descomprimir el .Zip Archivos adjuntos directamente en Outlook a través de VBA.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparar SQL Server y productos de software de reparación de Outlook. Para más información visite www.datanumen.com