Cómo imprimir rápidamente todos los archivos adjuntos de imágenes de un correo electrónico de Outlook en una sola página

Para ahorrar tinta y papel en la impresora, algunos usuarios desean imprimir todas las imágenes adjuntas en un correo electrónico en una sola página, en lugar de una imagen por página. Ahora, este artículo compartirá un medio para realizarlo.

Como todos sabemos, imprimir imágenes es desperdiciar bastante tinta de impresora. Por lo tanto, para ahorrar tinta y papel en la impresora, tal vez prefiera imprimir muchas imágenes adjuntas en la misma página en lugar de imprimir imágenes en páginas separadas. Aunque Outlook no ofrece esa función, aún puede lograrla de la siguiente manera.

Imprima todas las imágenes adjuntas de un correo electrónico de Outlook en una sola página

1. Para empezar, abre tu aplicación Outlook.
2. Luego, en la ventana de Outlook, toque los botones de tecla "Alt + F11".
3. A continuación, accederás a la ventana "Microsoft Visual Basic para Aplicaciones", en la que primero debes habilitar la "Biblioteca de objetos de Microsoft Word".
4. Después de eso, debe abrir un módulo que no se esté utilizando.
5. Posteriormente, copie y pegue el siguiente código VBA en este módulo.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Más tarde, puede volver a la lista de correo electrónico. Elija o abra un correo electrónico cuyas imágenes adjuntas desee imprimir.
7. Luego, active esta macro. En la ventana de macro actual, simplemente presione la tecla "F5" o haga clic en el icono "Ejecutar" en la barra de herramientas.
8. Finalmente, cuando la macro termine de ejecutarse, todos los archivos adjuntos de imágenes del correo electrónico de origen se imprimirán en una página, como la siguiente captura de pantalla:

Tratar con archivos corruptos de Outlook

Con más y más datos almacenados en su Outlook, su archivo de Outlook será cada vez más vulnerable. Puede verse comprometida debido a varios factores internos y externos. Además, es difícil predecir la corrupción de Outlook. Entonces, lo que puede hacer es asegurar un rescate inmediato y efectivo cuando se encuentre con corrupciones de Outlook. Por ejemplo, debe mantener un equipo especializado Reparación de PST herramienta, como DataNumen Outlook Repair en las inmediaciones. Escaneará y restaurará archivos dañados como una brisa.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperar Sql Server y productos de software de reparación de Outlook. Para más información visite www.datanumen.com