Cómo exportar rápidamente todos los hipervínculos en varios correos electrónicos de Outlook a Excel

Cuando necesitas extraer todos los hipervínculos de uno o más correos electrónicos, copiarlos uno por uno es una tontería. En este artículo te enseñaremos un método para exportar rápidamente todos los hipervínculos de varios correos electrónicos a Excel.

Por algunas razones, como registrar los hipervínculos en todos sus correos electrónicos enviados, deberá extraer los hipervínculos. Sin duda alguna, no es aconsejable extraerlos y copiarlos manualmente. Debe desear un enfoque mucho más inteligente, como usar VBA. Aquí le compartiremos un fragmento de código VBA, que puede exportar todos los hipervínculos en muchos correos electrónicos a Excel con un simple clic.

Exportar todos los hipervínculos en varios correos electrónicos a Excel

1. Para empezar, abre tu programa Outlook como de costumbre.
2. Luego, en la ventana de Outlook, debe presionar los botones de tecla "Alt + F11".
3. De inmediato, obtendrá acceso al editor de Outlook VBA.
4. Posteriormente, deberá habilitar la “Biblioteca de objetos de Microsoft Word” y la “Biblioteca de objetos de Microsoft Excel”. Haga clic en “Herramientas” > “Referencias” y, a continuación, habilítelas en el cuadro de diálogo emergente.
5. A continuación, debe abrir un módulo no utilizado, en el que debe copiar el código VBA a continuación en este módulo.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Después de eso, puede salir de la ventana actual del editor de VBA.
7. Más tarde, acceda a "Opciones de Outlook" para personalizar la barra de herramientas de acceso rápido y agregar la macro recién agregada a la barra de herramientas de acceso rápido.
8. Finalmente puedes tomar una foto:

• En primer lugar, en la lista de correo electrónico, seleccione los correos electrónicos cuyos hipervínculos desea extraer.
• Luego, haga clic en el botón de macro en la barra de herramientas de acceso rápido.
• Cuando finalice la macro, obtendrá un archivo de Excel, como la imagen a continuación:

Solucionar problemas inesperados de Outlook

Los problemas de Outlook pueden ocurrir de vez en cuando sin ningún presagio. Pero, en cuanto a errores pequeños, Outlook puede recuperarse con un simple reinicio o su herramienta de reparación de la bandeja de entrada. Pero si encuentra algunos problemas graves, los medios internos no surtirán efecto. En este punto, su último recurso es definitivamente una herramienta más confiable y sólida, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo mdf dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com