Cómo exportar rápidamente los detalles de todos los miembros de un grupo de contactos de Outlook a Excel

De manera predeterminada, solo puede ver los nombres de los miembros y las direcciones de correo electrónico en un grupo de contactos. Si desea obtener otros detalles de los miembros, puede utilizar la forma presentada en este artículo.

Cuando hace doble clic en un grupo de contactos para abrirlo, en su ventana, solo puede ver los nombres y las direcciones de correo electrónico de los miembros del grupo. No puede obtener otros detalles de los miembros, como la empresa, el cargo, el número de teléfono o la dirección comercial, etc. En general, para obtener estos detalles, debe buscar manualmente los contactos correspondientes a los miembros en su carpeta Contactos. Es demasiado problemático. Aquí le mostraremos un fragmento de código VBA, que puede exportar rápidamente estos detalles a un libro de Excel.

Exportar los detalles de todos los miembros de un grupo de contactos a Excel

1. A start con, inicie su aplicación Outlook.
2. Luego, debe presionar los atajos de teclado "Alt + F11" en la ventana principal de Outlook.
3. A continuación, en la nueva ventana "Microsoft Visual Basic para aplicaciones", debe abrir un módulo que no esté en uso o insertar directamente un módulo nuevo.
4. Posteriormente, copie y pegue el siguiente código VBA en este módulo.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Después de eso, para una verificación conveniente, puede agregar el nuevo proyecto de VBA a la barra de herramientas de acceso rápido o a la cinta.
6. Más tarde, establezca el nivel de seguridad de macros de Outlook en bajo.
7. En última instancia, puedes intentarlo.

• Primero, seleccione un grupo de contactos.
• Luego presione el botón macro en la barra de herramientas de acceso rápido o en la cinta.
• Inmediatamente, la macro se ejecutará.
• Cuando finalice, recibirá un mensaje de "¡Completado!"
• Después de eso, puede ir a la carpeta local de destino predefinida, en la que puede encontrar un nuevo archivo de Excel.
• Ábrelo, verás los detalles de contacto de los miembros del grupo como la siguiente captura de pantalla:

No se asuste ante los problemas de Outlook

Nadie está dispuesto a aceptar ningún problema de Outlook, sin importar el mensaje de error emergente o Outlook corrupto archivo de datos. Por lo tanto, los usuarios tenderán a entrar en pánico cuando se encuentren con problemas de Outlook. Si quieres mantener la calma en ese caso, debes tener dos necesidades a la mano. Uno son las copias de seguridad de datos actuales de Outlook. El otro es un potente software de corrección de Outlook, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperación de sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com