Cómo retrasar rápidamente el envío de correos electrónicos específicos hasta el horario laboral en su Outlook

Si necesita evitar enviar correos electrónicos específicos fuera del horario laboral, puede utilizar el método que se muestra en este artículo. Puede permitir que Outlook compruebe automáticamente si está en horario laboral cuando envía correos electrónicos específicos y lo retrasa hasta el horario laboral.

A veces, el momento en que redacta y envía un correo electrónico no está dentro de su horario laboral. En este caso, es posible que desee retrasar el envío de este correo electrónico hasta el siguiente horario laboral. Generalmente, puede utilizar la función nativa "Retrasar la entrega" para retrasar dichos correos electrónicos. Sin embargo, por ese medio, debe especificar el tiempo de entrega cada vez. Es demasiado molesto. A continuación, le compartiremos un fragmento de código VBA, que puede verificar automáticamente si está dentro del horario laboral cuando envía un correo electrónico específico y retrasar rápidamente su envío hasta el horario laboral.

Retrase rápidamente el envío de correos electrónicos específicos hasta el horario laboral

1. Desde el principio, inicie su programa Outlook.
2. Luego, en la pantalla principal emergente de Outlook, puede presionar las teclas "Alt + F11".
3. A continuación, obtendrá acceso al editor de Outlook VBA con éxito.
4. Después de eso, debe ubicar y abrir el proyecto "ThisOutlookSession".
5. Posteriormente, copie el siguiente código VBA en esta ventana del proyecto.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As MailItem
    Dim NewSendTime As String
    Dim bDelayMail As Boolean
    Dim nPrompt As Integer
 
    bDelayMail = True
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Work on specific emails only
       'You can change the conditions as per your needs
       If objMail.Recipients.Item(1).Address = "boss@datanumen.com" Then
 
          Select Case Weekday(Date, vbMonday)
                 'Delay 2 days if today is Saturday
                 Case 6
                      NewSendTime = (Date + 2) & " 09:00:00"
                 'Delay 1 days if today is Saturday
                 Case 7
                      NewSendTime = (Date + 1) & " 09:00:00"
                 Case Else
                      If DatePart("h", Now) < 9 Then
                         'Delay to 9 o'clock if now is too early
                         NewSendTime = Date & " 09:00:00"
                      ElseIf DatePart("h", Now) > 18 Then
                         Select Case Weekday(Date, vbMonday)
                                'Delay 3 days if today is Friday and now is over 6 PM
                                Case 5
                                     NewSendTime = (Date + 3) & " 09:00:00"
                                'Delay to 9 o'clock if now is before 6 PM
                                Case Else
                                     NewSendTime = (Date + 1) & " 09:00:00"
                         End Select
                      Else
                         bDelayMail = False
                      End If
            End Select
 
            If bDelayMail = True And objMail.DeferredDeliveryTime = "1/1/4501" Then
               'Ask if to delay sending this email
               nPrompt = MsgBox("Outside Working Hours:" & vbCrLf & "Do you want to delay this email until " & NewSendTime & "?", vbYesNo + vbExclamation, "Delay Email")
 
               If nPrompt = vbYes Then
                  objMail.DeferredDeliveryTime = NewSendTime
               Else
                  objMail.DeferredDeliveryTime = "1/1/4501"
               End If
           End If
       End If
    End If
End Sub

6. Posteriormente se le pedirá que asigne un certificado digital a este correo electrónico.
7. Y luego cambie su configuración de macro de Outlook para permitir las macros firmadas.
8. A partir de ahora, cada vez que envíe correos electrónicos que cumplan con los criterios predefinidos, si es fuera del horario laboral, recibirá un mensaje como la siguiente imagen:
9. Si selecciona "Sí", Outlook programará su envío hasta el horario laboral.

Rescatar archivos de Outlook dañados

Outlook se ha ganado muchos elogios debido a sus innumerables funciones. Sin embargo, todavía tiene un defecto mortal. Outlook es propenso a errores y corrupción. Por lo tanto, debe realizar una copia de seguridad de sus archivos de Outlook de forma regular. Puede evitar que sufra una dolorosa pérdida de datos de Outlook. Además, es mejor que consigas una poderosa herramienta de reparación, como DataNumen Outlook Repair, Que puede reparar Outlook problemas en segundos.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperación de mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com