Cómo adjuntar rápidamente las páginas específicas de un documento de Word a un correo electrónico de Outlook

MS Word tiene una función directa que ayuda a los usuarios a enviar el documento de Word actual como un archivo adjunto de correo electrónico. Pero a veces, es posible que solo espere adjuntar las páginas específicas de un documento de Word a un correo electrónico de Outlook. Ahora, este artículo te compartirá un método.

Para enviar un documento de Word completo como archivo adjunto de correo electrónico en la aplicación MS Word, simplemente puede ir al menú "Archivo" y cambiar a la pestaña "Guardar y enviar", debajo de la cual puede encontrar el botón "Enviar como archivo adjunto". Sin embargo, a veces, lo que desea enviar pueden ser solo páginas específicas del documento. En esta situación, puede usar el método que se presenta a continuación para lograrlo.

Adjunte las páginas específicas de un documento de Word a un correo electrónico

1. En primer lugar, debe abrir el documento de origen de Word cuyas páginas específicas desea enviar por correo electrónico.
2. Luego, después de ingresar a la ventana de MS Word, debe presionar los botones de tecla "Alt + F11".
3. A continuación, obtendrá acceso al editor de VBA en MS Word.
4. Después, debes habilitar la “Biblioteca de objetos de Microsoft Outlook”. Para ello, haz clic en “Herramientas” > “Referencias”.
5. Posteriormente, debe copiar el siguiente código VBA en un módulo que no esté en uso.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Finalmente, puede ejecutar esta macro. Simplemente presione el botón de la tecla F5 o toque el icono "Ejecutar" en la barra de herramientas.
7. Una vez que finalice la macro, se mostrará un nuevo correo electrónico de Outlook, que se adjunta con un extracto del documento de origen de Word, como la siguiente captura de pantalla:

Extraiga el máximo de datos de un archivo de Outlook dañado

Si ha utilizado Outlook durante décadas, es posible que se haya enfrentado a varios problemas de Outlook, incluidos mensajes de error internos emergentes, bloqueos repentinos y daños graves en los archivos. Debido al hecho de que el escaneo, herramienta de reparación incorporada, solo puede lidiar con los pequeños problemas, es mejor que tenga a mano una poderosa herramienta de reparación externa, digamos DataNumen Outlook Repair. Es capaz de extraer el máximo de datos del archivo de datos de Outlook dañado.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo corrección de sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com