Cómo mostrar las edades de las personas correspondientes para todos los eventos de cumpleaños en la vista de lista del calendario de Outlook

A algunos usuarios también les gustaría ver la edad de la persona correspondiente al ver un evento de cumpleaños en el calendario. Por lo tanto, en este artículo, compartiremos un método para hacer realidad esta idea con facilidad.

Cuando agrega la información de cumpleaños a un contacto, Outlook creará automáticamente un evento de cumpleaños en el calendario. En esta circunstancia, cada vez que vea eventos de cumpleaños en el calendario, es posible que también desee obtener las edades de las personas correspondientes. Así, aquí te presentaremos una forma de realizarlo.

Mostrar las edades de las personas correspondientes para todos los eventos de cumpleaños en la vista de lista

1. Al principio, inicie el editor de Outlook VBA.
2. Luego, copie el siguiente código en un módulo.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Después de eso, coloque el cursor en la primera subrutina y presione "F5" para ejecutar esta macro.
4. Cuando termine la macro, salga del editor de VBA y abra una carpeta de calendario.
5. Posteriormente, vaya a la pestaña "Ver" y haga clic en "Cambiar vista"> "Lista".
6. A continuación, haga clic en el botón "Ver configuración".
7. En el cuadro de diálogo emergente, elija "Columnas".
8. Luego, en el siguiente cuadro de diálogo de "Mostrar columnas", seleccione "Campos definidos por el usuario en la carpeta" de la lista de "Seleccionar campos disponibles de".
9. Más tarde, introduzca "Edad" en el cuadro "Columnas disponibles" y haga clic en el botón "Agregar ->".
10. Finalmente, haga clic en una serie de "Aceptar" hasta volver a la lista de elementos del calendario.
11. Ahora, en la lista, puede ver las edades de las personas de todos los eventos de cumpleaños, como se muestra en la siguiente figura.

Reparar archivo de Outlook comprometido

Puede entrar en pánico al encontrarse Outlook corrupto archivo que contiene muchos de sus valiosos correos electrónicos y horarios. A pesar de que tal problema es bastante desesperante, aún debe calmarse de inmediato y considerar medidas efectivas. Si sigue preocupado, la situación puede empeorar cada vez más. En realidad, hay varias formas y utilidades que pueden reparar el archivo dañado, como la herramienta de reparación de la bandeja de entrada y una herramienta más sólida y experimentada, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo SQL Server reparar y productos de software de reparación de Outlook. Para más información visite www.datanumen.com