Cómo recibir una notificación si no se recibe la respuesta de un correo electrónico específico dentro del tiempo previsto

Este artículo le enseñará un truco rápido sobre el uso de VBA para que Outlook le pregunte automáticamente si debe enviar un correo electrónico de notificación cuando no haya recibido la respuesta de un correo electrónico específico en un tiempo específico.

A veces, para los correos electrónicos de vital importancia, definitivamente esperará sus respuestas. En otras palabras, debe esperar que el destinatario pueda responderle lo antes posible. De lo contrario, siempre que no haya recibido la respuesta dentro del tiempo esperado, enviará nuevamente un correo electrónico de notificación de seguimiento al destinatario. Por lo tanto, en respuesta a este requisito, aquí presentaremos un método que usa VBA para hacer que Outlook le advierta automáticamente y le avise en tal caso. Siga leyendo para obtener los pasos y códigos elaborados.

Obtenga una notificación si no recibe la respuesta de un correo electrónico específico dentro del tiempo esperado

1. Al principio, start su Outlook.
2. Luego, debe establecer una hora de recordatorio específica para el correo electrónico específico.

• En primer lugar, haga clic derecho en el correo electrónico específico.
• Luego seleccione "Seguimiento"> "Agregar recordatorio".
• En el cuadro de diálogo, puede establecer la hora del recordatorio igual que la hora específica en la que desea recibir su respuesta.

3. Después de eso, presione los botones de tecla "Alt + F11" para acceder al editor de Outlook VBA.
4. A continuación, en la nueva ventana, abra el proyecto "ThisOutlookSession" y copie los siguientes códigos en él.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Posteriormente, firme este código.
6. Más tarde, cambie la configuración de macro de Outlook para permitir las macros firmadas digitalmente.
7. Eventualmente restart Outlook para activar la nueva macro. A partir de ahora, Outlook funcionará de la siguiente manera:

• Si ha recibido la respuesta del correo electrónico específico antes de que aparezca su recordatorio, Outlook borrará automáticamente la bandera y deshabilitará el recordatorio.
• Si no ha recibido la respuesta cuando se activa su recordatorio, Outlook le preguntará si debe enviar un correo electrónico de notificación de seguimiento. Si selecciona "Sí", se enviará el correo electrónico. Si selecciona "No", el mensaje desaparecerá de inmediato.

Resolver problemas molestos de Outlook

Como Outlook es propenso a errores, para evitar Corrupción de Outlook, es mejor que no solo confíe en la herramienta de bandeja de entrada, Scanpst.exe. Debe preparar otra herramienta de reparación potente y de buena reputación, como DataNumen Outlook Repair, que puede eliminar los molestos problemas que Scanpst.exe no puede resolver.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo corrupción sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com