Cómo exportar la estructura de carpetas de su archivo de Outlook a Excel

Comparte ahora:

Si desea exportar rápidamente la estructura de carpetas de su archivo de datos de Outlook a un libro de Excel, puede utilizar el método presentado en este artículo.

Por algunas razones, como registrar las carpetas y subcarpetas actuales de Outlook, muchos usuarios esperan exportar la estructura de carpetas de un archivo de Outlook a un archivo externo, como un libro de Excel. A continuación, le compartiremos un fragmento de código VBA, que puede ayudarlo a lograrlo en un santiamén.

Exportar la estructura de carpetas de su archivo de Outlook a Excel

Exportar la estructura de carpetas de su archivo de Outlook a Excel

  1. Para empezar, abre tu aplicación Outlook.
  2. Luego, en la ventana principal de Outlook, presione los botones de tecla "Alt + F11".
  3. A continuación, accederá al editor de Outlook VBA, en el que debe abrir un módulo no utilizado.
  4. Posteriormente, puede copiar el siguiente código VBA en este módulo.
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

Código VBA: exporte la estructura de carpetas de su archivo de Outlook a Excel

  1. Después de eso, debe asegurarse de que Outlook haya habilitado las macros.
  2. Eventualmente, puedes tomar una foto:
  • En la ventana de macro actual, presione el botón de la tecla F5.
  • Una vez que finalice la macro, recibirá una alerta que le indicará "Completar".
  • Más tarde, puede dirigirse a la carpeta local predefinida para buscar un nuevo archivo de Excel. Ábrelo y se verá como la siguiente captura de pantalla:Estructura de carpetas de su archivo de Outlook en Excel

Nunca ignore los errores de Outlook

A pesar de la cantidad de capacidades, Outlook es tan susceptible a errores y corrupción como otros clientes de correo electrónico. Por lo tanto, debe otorgar importancia a todos los errores en su Outlook. No los ignore, por favor. De lo contrario, la acumulación de errores puede provocar finalmente la corrupción de Outlook. Si se enfrenta a errores complicados, se sugiere utilizar una herramienta poderosa, como DataNumen Outlook Repair, Que puede reparar Outlook errores en segundos.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperación de sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com

Comparte ahora:

Los comentarios están cerrados.