Cómo configurar automáticamente Outlook en línea o sin conexión en función de sus horas de trabajo

A algunos usuarios les gustaría hacer que Outlook cambie automáticamente entre el estado en línea y fuera de línea en función de sus horas de trabajo. Entonces, en este artículo, compartiremos un método rápido con usted.

En realidad, configurar Outlook en línea o sin conexión es muy fácil. Para convertir Outlook en estado sin conexión, puede cambiar a la pestaña "Enviar / Recibir" y presionar el botón "Trabajar sin conexión". Y para volver al estado en línea, simplemente presione este botón nuevamente. Sin embargo, algunos usuarios esperan que Outlook pueda cambiar automáticamente al estado sin conexión cuando esté fuera del horario laboral y volver a conectarse en horario laboral. Aunque Outlook no proporciona dicha función, aún puede utilizar el siguiente código VBA para lograrlo.

Configuración automática de Outlook en línea o fuera de línea según sus horas de trabajo

1. Al principio, start su aplicación de Outlook.
2. Luego, después de obtener acceso a su Outlook, debe abrir su carpeta Tareas.
3. A continuación, debe crear un elemento de Tarea periódica diaria.

• Haga clic en el botón "Nueva tarea" en la cinta.
• Luego ingrese "Fuera de línea" en la línea de asunto de la tarea.
• A continuación, haga clic en el botón "Recurrencia" en la pestaña "Tarea".
• En el cuadro de diálogo emergente, seleccione el patrón de recurrencia "Diariamente", habilite "Sin fecha de finalización" y presione "Aceptar".
• A continuación, debe habilitar un recordatorio a las “5:00 PM”.
• Por último, presione el botón "Guardar y cerrar".

4. Posteriormente, debe crear otra Tarea periódica diaria llamada "En línea" y habilitar un recordatorio a las "8:00 a. M.", Como se muestra en la siguiente imagen:
5. Después de eso, en la ventana principal de Outlook, presione los botones de tecla "Alt + F11".
6. A continuación, obtendrá acceso al editor de Outlook VBA, en el que debe buscar y abrir el proyecto "ThisOutlookSession".
7. Luego, copie el siguiente código VBA en este proyecto.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Eventualmente, puedes restart Outlook para activar esta macro.
9. A partir de ahora, Outlook estará en línea en horario laboral y cambiará automáticamente al estado sin conexión fuera del horario laboral.

Su último recurso en caso de fallos de Outlook

Aunque Outlook cuenta con múltiples funciones, Outlook todavía no puede evitar errores y daños. Pero que no cunda el pánico. Siempre que tome las precauciones necesarias, podrá proteger sus datos de Outlook de forma eficaz. Por ejemplo, debe hacer una copia de seguridad de sus archivos PST con regularidad, ya que las copias de seguridad le permitirán recuperar PST corrupto datos. Además, mantener una poderosa herramienta de reparación, como DataNumen Outlook Repair, también es una cuestión de necesidad.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo arreglar mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com