Cómo configurar automáticamente diferentes tiempos de recordatorio para reuniones de Outlook en diferentes categorías de color

Si está clasificando las reuniones de Outlook por categorías de color y desea establecer una hora de recordatorio diferente para las reuniones en diferentes categorías de color, puede consultar este artículo. Aquí te enseñaremos a realizarlo con Outlook VBA.

Por ejemplo, supongamos que divides tus reuniones en dos grupos. Uno se clasifica como "Fuera de la oficina" porque la reunión está muy lejos, y el otro como "En la oficina" porque se celebra aquí mismo. Ahora, quieres que Outlook configure automáticamente el recordatorio para las reuniones "fuera de la oficina" una hora antes de que empiecen y para las reuniones "en la oficina" 15 minutos antes. A continuación, te mostraremos un método rápido para resolver este problema.

Configuración automática de recordatorios diferentes para reuniones en diferentes categorías de color

1. Para empezar, inicie su aplicación Outlook.
2. Luego, presione los botones de tecla "Alt + F11" para acceder a la ventana del editor de VBA.
3. A continuación, en la ventana siguiente, copie y pegue el código VBA a continuación en el proyecto "ThisOutlookSession".

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Posteriormente, deberá acceder a la subrutina "Application_Startup" y pulsar la tecla "F5" para ejecutar esta macro.
5. Desde entonces, cada vez que se agrega una nueva reunión al calendario predeterminado o cambia una reunión existente, Outlook verificará automáticamente las categorías de la reunión y establecerá automáticamente la hora de recordatorio diferente.

Eliminar errores de Outlook

Outlook puede presentar diversos problemas de vez en cuando. Por lo tanto, es fundamental que los usuarios aprendan a solucionarlos. Para empezar, conviene realizar copias de seguridad periódicas de los datos de Outlook. Además, si es posible, se recomienda mantener una copia de seguridad potente. Reparación de Outlook herramienta cercana, como DataNumen Outlook Repair. Puede escanear su archivo PST para descubrir problemas de Outlook y luego resolverlos con facilidad.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperación de sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com