Cómo mover automáticamente los correos electrónicos con destinatarios CC específicos en Outlook

En realidad, most de ustedes pueden esperar crear una regla de Outlook para mover automáticamente los correos electrónicos con destinatarios CC específicos. Pero la regla de Outlook no admite la verificación de destinatarios CC. Entonces, este artículo le enseñará cómo realizarlo con Outlook VBA.

Obviamente, es imposible que cree una regla de Outlook para buscar destinatarios CC específicos. Como se muestra en la siguiente captura de pantalla, para los correos electrónicos recibidos, solo puede verificar si su propio nombre está en el cuadro CC. De manera similar, para los correos electrónicos enviados, incluso no existe una condición de regla para marcar la casilla CC.

Por lo tanto, si desea configurar Outlook para mover automáticamente los correos electrónicos con destinatarios CC específicos, debe buscar otros medios. Luego. aquí te enseñaremos cómo lograrlo mediante Outlook VBA.

Mover automáticamente los correos electrónicos enviados con destinatarios CC específicos

1. En primer lugar, vaya a la pestaña "Desarrollador" y haga clic en el botón "Visual Basic".
2. Luego abra el proyecto "ThisOutlookSession" y copie los siguientes códigos VBA en él.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Posteriormente, debe proceder a firmar este código y cambiar la configuración de la macro como de costumbre.
4. Por último, puede salir de la ventana "Visual Basic". A partir de entonces, los correos electrónicos con los destinatarios CC específicos se moverán a la carpeta de correo especificada.

Mover automáticamente los correos electrónicos recibidos con destinatarios CC específicos

Ahora que el código VBA anterior tiene como objetivo mover los correos electrónicos enviados con destinatarios CC específicos, si desea buscar destinatarios CC específicos en los correos electrónicos recibidos y luego moverlos, debe usar los siguientes códigos.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Manténgase bien preparado para la corrupción de Outlook

Aunque Outlook tiene muchas funciones, todavía no puede ser inmune a la corrupción. Por lo tanto, debe mantenerse atento a todos los riesgos potenciales. Sin duda, el paso crítico debe ser realizar una copia de seguridad coherente y actualizada de los datos de Outlook. Además, debe mantener un herramienta de recuperación de Outlook corrupta en las proximidades. Será útil si fallan tanto las copias de seguridad como Scanpst.exe.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparación SQL Server error de archivo mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com