3 métodos para importar correos electrónicos desde una carpeta de Windows a su Outlook

Quizás haya guardado varios correos electrónicos de Outlook en su carpeta de Windows. Ahora, si desea volver a importarlos a una carpeta de Outlook, ¿cómo puede hacerlo? Este artículo le enseñará 3 formas.

Como todos sabemos, Outlook proporciona una opción incorporada, "Guardar como", mediante la cual puede guardar los correos electrónicos en la carpeta de Windows. Sin embargo, no existe ninguna función para volver a agregar los correos electrónicos exportados a la carpeta de Outlook. Por lo tanto, si desea importar los correos electrónicos de Outlook a Outlook, ¿cómo puede darse cuenta? A continuación, le enseñaremos 3 métodos. Puede elegir cualquiera según sus preferencias.

Método 1: Arrastrar y soltar para importar

1. Desde el principio, debe acceder a la carpeta de origen de Windows que almacena los correos electrónicos de Outlook que se importarán a Outlook.
2. Luego, inicie su aplicación Outlook.
3. A continuación, abra la carpeta de Outlook a la que desea importar los correos electrónicos.
4. Posteriormente, debe reducir tanto la ventana de la carpeta de Windows como la ventana de Outlook hasta que pueda verlas mientras tanto.
5. Después de eso, en la carpeta de Windows, puede seleccionar uno de los correos electrónicos de Outlook y luego presionar "Ctrl + A" para seleccionarlos todos.
6. Más tarde, puede arrastrar y soltar los correos electrónicos seleccionados a la carpeta visible de Outlook, como la siguiente captura de pantalla:
7. Finalmente, verá que todos los correos electrónicos de Outlook se han importado de la carpeta de Windows a la carpeta de Outlook, como se muestra en la siguiente imagen:

Método 2: use "CreateItemFromTemplate" en VBA

1. Para empezar, en la ventana principal de Outlook, pulse las teclas “Alt + F11”.
2. A continuación, obtendrá acceso a la ventana del editor de Outlook VBA.
3. Luego copie el siguiente código VBA en un módulo en blanco.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. A continuación, puede pulsar la tecla F5 en la ventana del módulo actual para iniciar la macro.
5. Después de eso, debe buscar la carpeta de origen de Windows en el cuadro de diálogo emergente.
6. Por último, después de seleccionar la carpeta de origen, todos los elementos de Outlook en esa carpeta se importarán a la carpeta de Outlook predefinida.
7. Nota: de esta manera, los correos electrónicos importados son todos nuevos correos electrónicos nuevos, que puede redactar a voluntad, como la siguiente captura de pantalla:

Método 3: utilizar "OpenSharedItem" en VBA

1. Al igual que el Método 2, copie los siguientes códigos VBA en otro módulo.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Luego ejecute esta macro presionando la tecla "F5".
3. A continuación, seleccione la carpeta de origen.
4. Finalmente, todos los correos electrónicos se importarán como se muestra en la siguiente imagen:

Comparaciones

Medios para bloquear la corrupción de datos PST

Como todos sabemos, Outlook viene preinstalado con una herramienta incorporada: escaneoLa mayoría de las veces, es capaz de resolver problemas pequeños. Sin embargo, si los problemas son extremadamente graves, la herramienta integrada tenderá a fallar. Por lo tanto, es mejor recurrir a una herramienta más potente, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo SQL Server corrupción y productos de software de reparación de Outlook. Para más información visite www.datanumen.com